Arduino.ru

Уже давно разрабатываю проект на досуге. Он никак не связан с основной работой, поэтому разработка идет медленно. Основная задумка - выращивать растения в закрытом боксе (огурцы, например, ага)

Собственно, еще не определился будет это гидропоника или земля.

Освещение планируется светодиодное 4 лампы по 54 ватта http://www.buyincoins.com/item/42980.html

С поливом еще точно не определился, но реализовано пока так: есть 2 датчика температуры, один сухой, другой влажный (неглубоко в земле), если разница между датчиками будет меньше указанной, то включается полив (на указанное время).

Реализовано 2 термостата (на тех же двух датчиках).

Освещение можно настроить на весь цикл выращивания (по дням, хоть на целый год)

Настройка производится через терминал (com порт) и сохраняется в EEPROM.

Лог ведется в текстовик на SD-карте (не проверял еще)

Управление нагрузками (свет, полив, нагреватели 1 и 2, охладители 1 и 2) производится через твердотельные реле (пока есть 3 штуки на 25 ампер) http://www.buyincoins.com/item/9224.html#.U98_mGPDAdU

Работа с часами реального времени DS3231 http://www.ebay.com/itm/281163978761?ssPageName=STRK:MEWNX:IT&_trksid=p3984.m1439.l2649

Уже давно разрабатываю проект на досуге. Он никак не связан с основной работой, поэтому разработка идет медленно.

Основная задумка - выращивать растения в закрытом боксе (огурцы, например, ага)

Собственно, еще не определился будет это гидропоника или земля.

Освещение планируется светодиодное 4 лампы по 54 ватта http://www.buyincoins.com/item/42980.html

С поливом еще точно не определился, но реализовано пока так: есть 2 датчика температуры, один сухой, другой влажный (неглубоко в земле), если разница между датчиками будет меньше указанной, то включается полив (на указанное время).

Реализовано 2 термостата (на тех же двух датчиках).

Освещение можно настроить на весь цикл выращивания (по дням, хоть на целый год)

Настройка производится через терминал (com порт) и сохраняется в EEPROM

Управление нагрузками (свет, полив, нагреватели 1 и 2, охладители 1 и 2) производится через твердотельные реле (пока есть 3 штуки на 25 ампер) http://www.buyincoins.com/item/9224.html#.U98_mGPDAdU

Работа с часами реального времени DS3231 http://www.ebay.com/itm/281163978761?ssPageName=STRK:MEWNX:IT&_trksid=p3984.m1439.l2649

 Вначале скетча есть определения для настройки функционала. Можно эмулировать ускоренное время, фейковую температуру датчиков, отключать запись на SD и вывод на LCD.

За лето достаточно хорошо оптимизировал код. Не очень разобрался со спящим режимом.

Вобщем, пока вываливаю все как есть. Походу разработки буду дополнять. Критика и советы приветствуются.

// Часы (3 варианта)
//#define TIME_FAKE   // время для отладки основного цикла, если вместе FAKE_TEMP = x3000 к скорости :)
//#define TIME_WD     // встроенный таймер, тикает раз в 8 секунд, без коррекции сильно отстает от реального (коррекция примерно +1 сек, +2 мин)
#define TIME_DS3231 // часы реального врмемени DS3231

#define FAKE_TEMP // Эмуляция показаний температуры
//#define SLEEPMODE // Работает вместе с TIME_WD, не отлажена работа с DS3231
#define LCD // Поддержка экранчика 16х2 (примерно +1100 байт) без LCD неверно работает DS3231
//#define SDCARD // Поддержка записи на SD карту (примерно +6740 байт)

// Выводы Arduino
const byte PIN_CS      = 4;  // Chip select для SD карты
const byte PIN_LATCH   = 8;  // Затвор сдвигового регистра (ST_CP)
const byte PIN_ONEWIRE = 9;  // Шина для датчиков температуры (OneWire)
const byte PIN_DATA    = 11; // Данные для сдвигового регистра (DS)
const byte PIN_CLOCK   = 12; // Тактирование сдвигового регистра (SH_CP)
const byte PIN_LED     = 13; // Индикаторный светодиод
// В разработке...
const byte PIN_POWER   = 6;  // Датчик наличия электроэнергии
const byte PIN_PIR     = 7;  // Датчик движения
const byte PIN_WATERCONTROL = A0; // Проверка уровня воды в резервуаре
const byte PIN_LIGHTCONTROL = A1; // Проверка уровня освещенности
const byte PIN_CO2CONTROL   = A2; // Проверка уровня углекислого газа
// A4, A5 зарезервированы для I2C

// Общее
#include <EEPROM.h>
#include <Streaming.h> // snprintf
#include <Wire.h>
const int DS3231_I2C_ADDRESS = 0x68;
char buf[30]; // Буфер для вывода snprintf

// Термодатчик DS18B20
#include <OneWire.h>
#include <DallasTemperature.h>
OneWire oneWire(PIN_ONEWIRE);
DallasTemperature sensors(&oneWire);

// Спящий режим
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>

// I2C LCD
#ifdef LCD
#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27,16,2);  // set the LCD address to 0x27 for a 16 chars and 2 line display
#endif

// SD карта
#ifdef SDCARD
#include <SD.h>
// On the Ethernet Shield, CS is pin 4. Note that even if it's not
// used as the CS pin, the hardware CS pin (10 on most Arduino boards,
// 53 on the Mega) must be left as an output or the SD library
// functions will not work.
byte sd_ready = false;
#endif

// Часы
byte day = 1;
byte hours = 0;
byte minutes = 0;
byte seconds = 0;

// Время в гексаминутах (так в 1 байт помещается любое время суток с точностью до 1/10 часа)
byte time = 0;       // Время суток
byte water_time = 0; // Время последнего полива

// Состояние системы
// 0 - работает
// 1 - цикл закончен
byte restart = false;

// Теплостаты
byte t_online[2] = {false, false};  // Наличие термодатчиков
float t_val[2] = {22.0, 23.5};      // Значение термодатчиков

// Сдвиговый регистр
byte switches = 0; // Состояние выводов сдвигового регистра
const byte LIGHT   = 0;
const byte WATER   = 1;
const byte T1_UP   = 2;
const byte T1_DOWN = 3;
const byte T2_UP   = 4;
const byte T2_DOWN = 5;

// Настройки (EEPROM)
const byte CONF_ADDR = 0; // Адрес размещения настроек в EEPROM
const byte CONF_VER  = 1; // Версия настроек. Для обнуляения настроек при перепрошивке.
struct ConfigStruct {
  byte version;
  float t_min[2];
  float t_max[2];
  float wd;  // Разница температур, как условие для полива. Если разница небольшая, то датчик в земле сухой.
  byte wp; // Время проверки необходимости полива в гексаминутах.
  byte wt; // Время длительности полива в секундах.
  byte light[3]; // Световая схема на каждый из ### дней. В гексаминутах.
} config = {
  CONF_VER, 
  {22.00, 21.00}  , 
  {26.00, 26.00}  , 
  1.50, 10, 1, // Полив каждый час, если разница датчиков меньше 1.5 градуса, длительность полива 1 секунда
  {180,120,60}  , // Продолжительность дня в гексоминутах. День начинается с полуночи. 120 гексаминут = 12 часов
};

// Прерывания
#ifdef TIME_WD
ISR(WDT_vect) {
  digitalWrite(PIN_LED, !digitalRead(PIN_LED));
}
#endif

// Управление через терминал
void serialEvent() {
  float t = 0;
  int num = 0;
  char cmd, param;
  byte light_h, light_m;

  while (Serial.available()) {
    cmd = Serial.read();
    Serial << "Command: " << cmd << endl;
    switch (cmd) {
    case 'l': // Настройки плана освещения light2=12:00
      num = Serial.parseInt();
      if (num < 1 || num > sizeof(config.light)) {
        break;
      }
      light_h = Serial.parseInt();
      light_m = Serial.parseInt();
      config.light[num - 1] = light_h * 10 + light_m / 6;
      time_to_buf(light_h, light_m);
      Serial << "Set light: " << num << " to " << buf << endl;
      break;
    case 'r':
      param = Serial.read();
      switch (param) {
      case 'e': // restart
        restart = true;
        day = 1;
        break;
      case 't': // Установить время rtc=1:12:34:56
        day = Serial.parseInt();
        hours = Serial.parseInt();
        minutes = Serial.parseInt();
        seconds = Serial.parseInt();
#ifdef TIME_DS3231
        ds3231_settime();
#endif
        break;
      }
      break;
    case 's':
      param = Serial.read();
      switch (param) {
      case 't': // status
        status_show();
        break;
      case 'a': // save
        config_save();
        break;
      case 'w': // switches
        do_log();
        break;
      }
      break;
    case 'w': // watering settings
      param = Serial.read();
      switch (param) {
      case 'p': // wp
        config.wp = Serial.parseInt(); // watering period
        break;
      case 't': // wt
        config.wt = Serial.parseInt(); // watering time (in seconds)
        break;
      case 'd': // wd
        config.wd = Serial.parseFloat(); // разница температур для полива
        break;
      }
      break;
    case 't': // Примеры: t1=25.3 t2max=28 t1min=22.5
      // t1, t2
      num = Serial.parseInt();
      if (num < 1 || num > sizeof(t_online)) {
        break;
      }
      // min=, max=
      param = Serial.read();
      if (param == 'm') {
        param = Serial.read();
        t = Serial.parseFloat();
        switch (param) {
        case 'i': // min
          config.t_min[num - 1] = t;
          break;
        case 'a': // max
          config.t_max[num - 1] = t;
        }
      } 
      #ifdef FAKE_TEMP
      else { // =
        t_val[num - 1] = Serial.parseFloat();
      }
      #endif
      break;
    default:
      Serial << "Ask zagzag2008@gmail.com for commands ;)" << endl;
    }
    
    while (Serial.available()) {
      Serial.read();
    }
//    Serial.flush();
  }
}

void setup() {
  pinMode(PIN_LED,   OUTPUT);
  pinMode(PIN_LATCH, OUTPUT);
  pinMode(PIN_CLOCK, OUTPUT);
  pinMode(PIN_DATA,  OUTPUT);

#ifdef SDCARD
  pinMode(10, OUTPUT);
  sd_ready = SD.begin(PIN_CS); // Попробовать перенести инициализацию в функцию do_log
#endif

#ifdef LCD
  lcd.init();
  lcd.backlight();
#endif

#ifdef TIME_WD
  // Watchdog timer
  MCUSR &= ~(1<<WDRF); /* Clear the reset flag. */
  WDTCSR |= (1<<WDCE) | (1<<WDE);
  WDTCSR = 1<<WDP0 | 1<<WDP3; /* 8.0 seconds */
  /* set new watchdog timeout prescaler value */
  WDTCSR |= _BV(WDIE); /* Enable the WD interrupt (note no reset). */
#endif

  Serial.begin(9600);
  sensors.begin();
  ds3231_gettime();
  config_load();
  status_show();

#ifdef RTC_3231
  Wire.begin();
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0x0E);
//  Wire.write(B00000000);
//  Wire.write(B10001000);
  Wire.write(B00011100); // ####Разобраться с флагами!
  Wire.endTransmission();
#endif
}

void loop() {
#ifdef TIME_FAKE
  seconds += 60;
  delay(10);

  // Обработчик часов и дней
  if (seconds >= 60) {
    minutes++; 
    seconds -= 60;
    if (minutes == 60) { 
      hours++; 
      minutes = 0;
      if (hours == 24) { 
        day++; 
        hours = 0; 
        if (day > sizeof(config.light)) { 
          restart = true; 
        } 
      } 
    }
#endif

#ifdef TIME_WD
  seconds += 8; // Watchdog срабатывает каждые 8 секунд
  // Обработчик часов и дней
  if (seconds >= 60) {
    minutes++; 
    seconds -= 59; // подобранное значение для коррекции
    if (minutes == 60) { 
      hours++; 
      minutes = 2; // подобранное значение для коррекции
      if (hours == 24) { 
        day++; 
        hours = 0; 
        if (day > sizeof(config.light)) { 
          restart = true; 
        } 
      } 
    }
#endif

#ifdef TIME_DS3231
  if (ds3231_gettime() == true) { // ds3231_gettime - TRUE при смене минуты
#endif

    // Текущее время в гексаминутах, округляем, да.
    time = hours * 10 + minutes / 6; // В одном часе 10 гексаминут

    // Свет
    switch_set(LIGHT, ((time < config.light[day - 1]) ? HIGH : LOW));

    // Опрос термометров
#ifdef FAKE_TEMP
    t_online[0] = true;
    t_online[1] = true;
#else
    sensors.requestTemperatures();

    //    byte c = sensors.getDeviceCount();
    //    for (byte num = 0; num < c; num++) {
    for (byte num = 0; num < sizeof(t_online); num++) {
      t_val[num] = sensors.getTempCByIndex(num);
      t_online[num] = ((t_val[num] == -127.00) ? true : false);
    }
#endif

    // Полив
    if (t_online[0] == true && t_online[1] == true) {
      if (abs(t_val[0] - t_val[1]) < config.wd) {
        if (abs(time - water_time) >= config.wp) {
          water_time = time;
          switch_set(WATER, HIGH);
          delay(config.wt * 1000);
          switch_set(WATER, LOW);
        }
      }
    }

    // Термостат
    if (t_online[0] == true) {
//      switch_set(T1_DOWN, ((t_val[0] > config.t_max[0]) ? HIGH : LOW));
//      switch_set(T1_UP, ((t_val[0] < config.t_min[0]) ? HIGH : LOW));
      switch_set(T1_DOWN, t_val[0] > config.t_max[0]);
      switch_set(T1_UP, t_val[0] < config.t_min[0]);
    }

    if (t_online[1] == true) {
//      switch_set(T2_DOWN, ((t_val[1] > config.t_max[1]) ? HIGH : LOW));
//      switch_set(T2_UP, ((t_val[1] < config.t_min[1]) ? HIGH : LOW));
      switch_set(T2_DOWN, t_val[1] > config.t_max[1]);
      switch_set(T2_UP, t_val[1] < config.t_min[1]);
    }

    // Сообщения об ошибках
#ifdef LCD
    lcd.setCursor(0, 1);
    for (byte num = 0; num < sizeof(t_online); num++) {
      if (num > 0) { 
        lcd << ", "; 
      }
      lcd << "T" << (num + 1) << " n/a";
    }
#endif
  }

#ifdef LCD
  time_to_buf();
  lcd.home();
  lcd << buf;
#endif

  // Цикл завершен?
  if (restart) {
    Serial << "Cycle restarted. Complete " << (day - 1) << " of " << sizeof(config.light) << " days." << endl;
    restart = false;
    day = 1;
  }

#ifdef SLEEPMODE
  do_sleep(); // В спящий режим
#endif
}

// Функции
void time_to_buf() {
  snprintf(buf, sizeof(buf), "%03d:%02d:%02d:%02d", day, hours, minutes, seconds);
}

void time_to_buf(byte h, byte m) {
  snprintf(buf, sizeof(buf), "%02d:%02d", h, m);
}

void status_show() {
  Serial << "Temperatures:" << endl;
  for (byte num = 0; num < sizeof(t_online); num++) {
    Serial << (num + 1) << " (" << ((t_online[num] == true) ? "on" : "off") << ") = " << t_val[num] << ". min = " << config.t_min[num] << ", max = " << config.t_max[num] << endl;
  }

  byte water_time_h = water_time / 10;
  byte water_time_m = (water_time % 10) * 6;
  time_to_buf(water_time_h, water_time_m);
  Serial << "Watering " << config.wt << " sec. every " << (config.wp * 6) << " min. if difference of temp. < " << _FLOAT(config.wd, 2) << endl 
         << "Last watering: " << buf << endl;

  Serial << "Light: ";
  byte light_time_h = 0, light_time_m = 0;
  for (byte num = 0; num < sizeof(config.light); num++) {
    light_time_h = config.light[num] / 10;
    light_time_m = (config.light[num] % 10) * 6;
    time_to_buf(light_time_h, light_time_m);
    Serial << (num + 1) << '=' << buf << ' ';
  }
  Serial << endl;
}

// CONFIG
void config_load() {
  Serial << "Config: ";
  if (EEPROM.read(CONF_ADDR) != CONF_VER) {
    Serial << "DEFAULT";
  } 
  else {
    for (unsigned int t = 0; t < sizeof(config); t++)
      *((char *)&config + t) = EEPROM.read(CONF_ADDR + t);
    Serial << "EEPROM";
  }
  Serial << endl;
}

void config_save() {
  for (unsigned int t = 0; t < sizeof(config); t++) {
    EEPROM.write(CONF_ADDR + t, *((char *)&config + t));
  }
  Serial << "Config saved!" << endl;
}

void switch_set(byte pos, byte state) {
  static byte switches_old = 0;

  bitWrite(switches, pos, state);
  if (switches == switches_old) {
    return;
  }

  switches_old = switches;
  digitalWrite(PIN_LATCH, LOW);
  shiftOut(PIN_DATA, PIN_CLOCK, MSBFIRST, switches); // MSBFIRST - с первого (левого) бита
  digitalWrite(PIN_LATCH, HIGH);
  do_log();
}

#ifdef SLEEPMODE
void do_sleep(void) {
  Serial.flush();
  set_sleep_mode(SLEEP_MODE_IDLE);
  sleep_enable();
  // Отрубаем лишнюю периферию
  power_adc_disable();
  power_spi_disable();
  power_timer0_disable();
  power_timer1_disable();
  power_timer2_disable();
  power_twi_disable();
  sleep_mode();
  sleep_disable();
  power_all_enable();
}
#endif

void do_log() {
  time_to_buf();
  Serial << buf;
#ifdef SDCARD
  File dataFile = SD.open("log.txt", FILE_WRITE);
  if (dataFile) {
    dataFile << buf;
  }
#endif
  snprintf(buf, sizeof(buf), " light=%d water=%d t1_up=%d ", bitRead(switches, LIGHT), bitRead(switches, WATER), bitRead(switches, T1_UP));
  Serial << buf;
#ifdef SDCARD
  if (dataFile) {
    dataFile << buf;
  }
#endif
  snprintf(buf, sizeof(buf), "t1_down=%d t2_up=%d t2_down=%d\n", bitRead(switches, T1_DOWN), bitRead(switches, T2_UP), bitRead(switches, T2_DOWN));
  Serial << buf;
#ifdef SDCARD
  if (dataFile) {
    dataFile << buf;
    dataFile.close();
  }
#endif
}

#ifdef TIME_DS3231
boolean ds3231_gettime() {
  static byte rtc_day = 0, rtc_day_prev = 0, minutes_prev = 0;
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0x00);
  Wire.endTransmission();
  Wire.requestFrom(DS3231_I2C_ADDRESS, 4);

  if (Wire.available()) {
    seconds = Wire.read();
    minutes = Wire.read();
    hours   = Wire.read();
    rtc_day = Wire.read();
    seconds = (((seconds & B11110000) >> 4) * 10 + (seconds & B00001111));
    minutes = (((minutes & B11110000) >> 4) * 10 + (minutes & B00001111));
    hours   = (((hours & B00110000) >> 4) * 10 + (hours & B00001111));
    rtc_day = (rtc_day & B00000111); // 1-7

    if (rtc_day != rtc_day_prev) {
      if (rtc_day_prev != 0) { // При запуске не прибавляем еще один день
        day++;
        if (day > sizeof(config.light)) {
          restart = true;
        }
      }
      rtc_day_prev = rtc_day;
    }
  }
  if (minutes != minutes_prev) {
    minutes_prev = minutes;
    return true;
  } else {
    return false;
  }
}
void ds3231_settime() {
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0x00);
  Wire.write(decToBcd(seconds));
  Wire.write(decToBcd(minutes));
  Wire.write(decToBcd(hours));
  Wire.endTransmission();

}
byte decToBcd(byte val) {
  return ((val / 10 * 16) + (val % 10));
}
#endif