Arduino.ru

Так покажите что вы уже написали и что - где не получается.

Не могу написать программу

А Вы пробовали?

Я писал

Не могу написать программу для ардуино, а именно. 1 кнопка включает цикл ,10 минут св.диод горит, 5 минут не горит и так по кругу. но нажав кнопку 2,первый цикл отключается а второй, св.диод горит 20 мин. и 10 отдыхает и также по кругу. Помогите пожалуйста лузеру))

Я сам электрик по оброзованию.(подходит ко мне бабушка и просит заменить лампочку

/* to_juk.ino
  #1 2 мигалки ->13
  #2 кнопка ->2
  #3 кнопка ->3
  Принцип кода:1 включаем - ничего не мигает
               2 нажимает кнопку 1 => мигает 0.3 s горит 0.3 s не горит
               3 нажимает кнопку 2 => мигает 1s    горит   1 s не горит
*/
//#1 светодиод
#include "Cl_Blink.h"
#define LED_PIN 13
Cl_Blink Blink1(LED_PIN, 0, 300, 300); // (пин,логика,время Led ON,время Led ON) /создать мигающий светодиод на пине 13
Cl_Blink Blink2(LED_PIN, 0,1000,1000); // (пин,логика,время Led ON,время Led ON) /создать мигающий светодиод на пине 13
void func1() {
  Blink2.OFF();
  Blink1.ON();
}
void func2() {
  Blink1.OFF();
  Blink2.ON();
}
//#2 кнопка 1
#include "Cl_press_btn.h"
#define BTN1_PIN 2
Cl_press_btn Btn1(BTN1_PIN); // создать кнопку на пине 2
//#3 кнопка 1
#define BTN2_PIN 3
Cl_press_btn Btn2(BTN2_PIN); // создать кнопку на пине 3

void setup() {
  //#1 светодиод
  Blink1.setup();
  Blink2.setup();
  //#2 кнопка
  Btn1.setup();
  //#3 кнопка
  Btn2.setup();
}
void loop() {
  //#1 светодиод
  Blink1.loop();
  Blink2.loop();
  //#2 кнопка
  Btn1.loop(& func1);
  //#3 кнопка
  Btn2.loop(& func2);
}

/*Cl_Blink.cpp
*/
#include "Arduino.h"
#include "Cl_Blink.h"
Cl_Blink::Cl_Blink(byte _pin, bool _logic, uint32_t _time_ON, uint32_t  _time_OFF) {
  led_pin = _pin;
  logic = _logic;
  time_ON =  _time_ON;
  time_OFF =  _time_OFF;
}
void Cl_Blink::setup(void) {
  pinMode(led_pin, OUTPUT)     ;// подключить cветодиод
  digitalWrite(led_pin, led = 0) ; // выключить светодиод
  blink = 0 ; // выключить мигание
}
void Cl_Blink::loop(void ) {
  if (blink && led && millis() - past > time_ON) {
    past = millis();
    digitalWrite(led_pin, led = 0);
  }
  if (blink && ! led && millis() - past > time_OFF) {
    past = millis();
    digitalWrite(led_pin, led = 1);
  }
}
void Cl_Blink::ON(void ) {
  blink = 1;
  past = millis();
  digitalWrite(led_pin, led = 1);
}
void Cl_Blink::OFF(void ) {
  blink = 0;
  digitalWrite(led_pin, led = 0);
}

/*Cl_Blink.h
*/
#ifndef Cl_Blink_h
#define Cl_Blink_h

#include "Arduino.h"
class Cl_Blink {
  public:
    Cl_Blink(byte _pin, bool _logic, uint32_t _time_ON, uint32_t  _time_OFF); // конструктор
    void setup(void); // поставить в setup()
    void loop(void) ; // поставить в loop()
    void ON(void)   ; // включить мигание
    void OFF(void)  ; // выключить мигание
  private:
    bool logic     ; //  при 0 светодиод горит при 1 //  при 1 светодиод горит при 0
    byte led_pin   ; // нога светодиода
    bool led       ; // состояние светодиода
    bool blink = 0 ; // 1 мигание / 0 нет
    uint32_t time_ON, time_OFF  ; // время  Led ON, время  Led OFF
    uint32_t past = 0 ;
};
#endif //Cl_Blink_h

/*Cl_press_btn.cpp
*/
#include "Arduino.h"
#include "Cl_press_btn.h"
Cl_press_btn::Cl_press_btn(byte _pin) {
  btn_pin = _pin;
}
void Cl_press_btn::setup() {
  pinMode(btn_pin, INPUT_PULLUP);// подключить кнопку 1 с подтяжкой
  btn = digitalRead(btn_pin) ; // прочитать реальное значение на выводе
}
void Cl_press_btn::loop(void (* _func_1)()) {
  if (! bounce_btn && btn != digitalRead(btn_pin)) { // если прошел фронт изм на выводн
    bounce_btn = 1;                                 // выставить флаг
    past = millis();                         // сделать временую засветку
  }
  else if ( bounce_btn && millis() - past >= 5 ) { // если прошло антидребезговое время
    bounce_btn = 0;      // то снять флаг
    btn_old = btn ;
    btn = digitalRead(btn_pin) ; // прочитать реальное значение на выводе
    if (btn_old && ! btn) _func_1()  ;
  }
}

/*Cl_press_btn.h
*/
#ifndef Cl_press_btn_h
#define Cl_press_btn_h

#include "Arduino.h"
class Cl_press_btn {
  public:
    Cl_press_btn(byte _pin);
    void setup();
    void loop(void (* _func_1)());
  private:
    byte btn_pin ;
    bool btn, btn_old;
    bool bounce_btn = 0; // антидребезговый флаг
    uint32_t past = 0 ;
};
#endif //Cl_press_btn_h

/* to_juk.ino
  #1 2 мигалки ->13
  #2 кнопка ->2
  #3 кнопка ->3
  Принцип кода:1 включаем - ничего не мигает
               2 нажимает кнопку 1 => мигает 0.3 s горит 0.3 s не горит
               3 нажимает кнопку 2 => мигает 1s    горит   1 s не горит
*/
//#1 светодиод
#include "Cl_Blink.h"
#define LED_PIN 13
Cl_Blink Blink1(LED_PIN, 0, 300, 300); // (пин,логика,время Led ON,время Led ON) /создать мигающий светодиод на пине 13
Cl_Blink Blink2(LED_PIN, 0,1000,1000); // (пин,логика,время Led ON,время Led ON) /создать мигающий светодиод на пине 13
void func1() {
  Blink2.OFF();
  Blink1.ON();
}
void func2() {
  Blink1.OFF();
  Blink2.ON();
}
//#2 кнопка 1
#include "Cl_press_btn.h"
#define BTN1_PIN 2
Cl_press_btn Btn1(BTN1_PIN); // создать кнопку на пине 2
//#3 кнопка 1
#define BTN2_PIN 3
Cl_press_btn Btn2(BTN2_PIN); // создать кнопку на пине 3

void setup() {
  //#1 светодиод
  Blink1.setup();
  Blink2.setup();
  //#2 кнопка
  Btn1.setup();
  //#3 кнопка
  Btn2.setup();
}
void loop() {
  //#1 светодиод
  Blink1.loop();
  Blink2.loop();
  //#2 кнопка
  Btn1.loop(& func1);
  //#3 кнопка
  Btn2.loop(& func2);
}

/*Cl_Blink.cpp
*/
#include "Arduino.h"
#include "Cl_Blink.h"
Cl_Blink::Cl_Blink(byte _pin, bool _logic, uint32_t _time_ON, uint32_t  _time_OFF) {
  led_pin = _pin;
  logic = _logic;
  time_ON =  _time_ON;
  time_OFF =  _time_OFF;
}
void Cl_Blink::setup(void) {
  pinMode(led_pin, OUTPUT)     ;// подключить cветодиод
  digitalWrite(led_pin, led = 0) ; // выключить светодиод
  blink = 0 ; // выключить мигание
}
void Cl_Blink::loop(void ) {
  if (blink && led && millis() - past > time_ON) {
    past = millis();
    digitalWrite(led_pin, led = 0);
  }
  if (blink && ! led && millis() - past > time_OFF) {
    past = millis();
    digitalWrite(led_pin, led = 1);
  }
}
void Cl_Blink::ON(void ) {
  blink = 1;
  past = millis();
  digitalWrite(led_pin, led = 1);
}
void Cl_Blink::OFF(void ) {
  blink = 0;
  digitalWrite(led_pin, led = 0);
}

/*Cl_Blink.h
*/
#ifndef Cl_Blink_h
#define Cl_Blink_h

#include "Arduino.h"
class Cl_Blink {
  public:
    Cl_Blink(byte _pin, bool _logic, uint32_t _time_ON, uint32_t  _time_OFF); // конструктор
    void setup(void); // поставить в setup()
    void loop(void) ; // поставить в loop()
    void ON(void)   ; // включить мигание
    void OFF(void)  ; // выключить мигание
  private:
    bool logic     ; //  при 0 светодиод горит при 1 //  при 1 светодиод горит при 0
    byte led_pin   ; // нога светодиода
    bool led       ; // состояние светодиода
    bool blink = 0 ; // 1 мигание / 0 нет
    uint32_t time_ON, time_OFF  ; // время  Led ON, время  Led OFF
    uint32_t past = 0 ;
};
#endif //Cl_Blink_h

/*Cl_press_btn.cpp
*/
#include "Arduino.h"
#include "Cl_press_btn.h"
Cl_press_btn::Cl_press_btn(byte _pin) {
  btn_pin = _pin;
}
void Cl_press_btn::setup() {
  pinMode(btn_pin, INPUT_PULLUP);// подключить кнопку 1 с подтяжкой
  btn = digitalRead(btn_pin) ; // прочитать реальное значение на выводе
}
void Cl_press_btn::loop(void (* _func_1)()) {
  if (! bounce_btn && btn != digitalRead(btn_pin)) { // если прошел фронт изм на выводн
    bounce_btn = 1;                                 // выставить флаг
    past = millis();                         // сделать временую засветку
  }
  else if ( bounce_btn && millis() - past >= 5 ) { // если прошло антидребезговое время
    bounce_btn = 0;      // то снять флаг
    btn_old = btn ;
    btn = digitalRead(btn_pin) ; // прочитать реальное значение на выводе
    if (btn_old && ! btn) _func_1()  ;
  }
}

/*Cl_press_btn.h
*/
#ifndef Cl_press_btn_h
#define Cl_press_btn_h

#include "Arduino.h"
class Cl_press_btn {
  public:
    Cl_press_btn(byte _pin);
    void setup();
    void loop(void (* _func_1)());
  private:
    byte btn_pin ;
    bool btn, btn_old;
    bool bounce_btn = 0; // антидребезговый флаг
    uint32_t past = 0 ;
};
#endif //Cl_press_btn_h

Как же ему не попёрло, что разобиделся как гимназистка и ушёл Вас не дождавшись.

Я не для него делал. Я просто его условие задачи взял для отработки решения подобных задач. Не было его, взял бы другую . Тем более вот пришел и за пару часов нарисовал решение.