Arduino.ru

«Есть у Льва Николаевича Толстого, среди множества алмазов народной речи, в одном из произведений такая поговорка: "Баба с печи летит, семьдесят семь дум передумает. Сколько там с той печи лететь? И то — семьдесят семь дум!" Михалевич, Высокие низы. [Матрена:]»

Если, например, возьмем высоту печи 1,5 м (поправьте, кто лучше знает), то по формуле школьного учебника физики получается, что лететь Матрене всего t=sqrt(2*h/g) = sqrt(2*1.5/9.8) = 0.6 сек.

Отсюда легко посчитать, что на одну думу затрачивается t=0,6/77 = 0.008 сек, или примерно восемь миллисекунд.

Кнопка - она женского рода, поэтому даже самые идеальные кнопки в первые мгновения на ласковое нажатие и простой и прямой вопрос ДА? начинают суетиться  и дергаться, лихорадочно менять свое состояние, тоже, может быть, сто раз за секунду, чтобы, в конце концов, вынести мОзги, так ничего внятного не ответив :(((
Это явление в технике называется "дребезг" и обычно с ним предлагают бороться следующим образом.

Опрашивают состояние кнопки, и если оно ДА, через какое-то время опрашивают снова. Если получен утвердительный ответ ДА во второй раз - нужно немедленно действовать. Если получено НЕТ – задавать вопрос сначала уже в следующем цикле.

Промежуток времени между двумя запросами каждый определяет самостоятельно. Одни засекают время, запускают таймер и продолжают заниматься своими делами пока не подойдет время второго запроса. Другие бросают все дела, тупо зависают на время задержки (см. функцию delay()), и только потом задают второй вопрос.

Первый способ хорош, когда у тебя много других дел и нет возможности их бросить и просто ждать заданный интервал.

Второй способ подойдет тем, кому некуда торопиться.  Например, в системе полива цветов ±10 сек или даже минут никакой роли не играют.

Я предлагаю еще один способ опроса состояния кнопки.

Если первый ответ отрицательный - дальше не имеет смысла опрашивать, и продолжаем выполнять луп.

Если вдруг прозвучало "ДА" - бросаем все дела и снова и снова (допустим, 255 раз) спрашиваем: "ты действительно говоришь ДА?". Если все ответы подряд положительны и кнопка твердо согласна - начинаем обрабатывать согласие. Если хоть один ответ был отрицательный - ловить нам нечего, бросаем окучивать кнопку и продолжаем луп.

Собственно, здесь приложен скетч тестового примера.

/*
 * DigitalReadSerial
 * Reads a digital input on pin 2, prints the result to the serial monitor
 * This example code is in the public domain.
 *
 * Среда разработки {The Arduino Integrated Development Environment - or Arduino Software (IDE)}
 * идентифицирует плату как Arduino Uno/Genuino Uno
 * 
*/

/*                        ТЕСТОВЫЙ ПРИМЕР
   Подавление дребезга кнопки методом последовательных совпадений
   Состояние кнопки многократно "N" раз считывается digitalRead()
   Если последующее чтение не совпадает с предыдущим - цикл обнуляется,
   опрос состояния кнопки прекращается
   Если все N последовательных опросов дают одинаковый результат -
   выводится сообщение о нажатии кнопки,
   на 1000 мсек = 1 сек зажигается LED 13-го пина
*/

#define RESET_ALL 11                                        // пин моей кнопки "RESET_ALL"
const boolean default_RESET_ALL = LOW ;                     // исходное состояние нормально разомкнутой кнопки
                                                            // RESET_ALL с подтягиванием к земле
unsigned int numberOfCycles = 65535 ;                       // максимальное допустимое число повторений digitalRead() 


// the setup routine runs once when you press reset:
// Запуск делается с нажатой кнопкой RESET_ALL

void setup() {
  Serial.begin(9600) ;                                      // initialize serial communication at 9600 bits per second:
  pinMode(RESET_ALL, INPUT) ;                               // make the pushbutton's pin an input:
  pinMode(13, OUTPUT) ;
  digitalWrite(13, LOW) ;
  }

void loop() {                                               // the loop routine runs over and over again Forever!
  if (ladyButton(RESET_ALL,                                 // сравнивается текущее состояние кнопки
                 default_RESET_ALL,                         // с дефолтным
                 255 )                                      // максимальное число повторений в примере
                 == !default_RESET_ALL ) {                  // если состояние стабильно изменилось -
    Serial.println ("Button is pressed !") ;                // выводим сообщение
    digitalWrite(13, HIGH) ;                                // включаем 13 пин,
    delay(1000) ;                                           // смотрим на него 1 сек
    digitalWrite(13, LOW) ;                                 // и выключаем 13 пин     
    }
  }


// Функция многократного непрерывного опроса кнопки

boolean ladyButton(int nomberPin, boolean defaultState, unsigned int numberOfCycles)
  {                                                         // nomberPin номер опрашиваемого цифрового пина
                                                            // defaultState исходное состояние кнопки/пина
                                                            // numberOfCycles число повторений опросов состояния кнопки
  unsigned int i = 0 ;                                      // счетчик текущего номера цикла чтения кнопки
  boolean pushState ;                                       // возвращаемое состояние кнопки
  while (i < numberOfCycles) {                              // запускается циклический опрос
    if (digitalRead(nomberPin) == !defaultState) {          // если кнопка изменила исходное состояние -
      i = i + 1 ;                                           // наращивается счетчик текущего номера цикла
      }
    else {                                                  // если было несовпадение -
      break ;                                               // выходим из проверки
      }                                                     // значит переходной процесс не закончился         
    }                                                       // и незачем тратить время на следующие запросы

  if (i == numberOfCycles) {                                // если все подряд опросы == ДА - нам повезло
    pushState = !defaultState;                              // и кнопка хорошо нажата
    }           
  else {                                                    // если хоть раз НЕТ - ждем следующего случая
    pushState = defaultState;                               // и кнопка не нажата
    }                       
  return pushState ;                                        // возвращаем результат опроса состояния кнопки 
  }

/* Один из результатов прогона 09.02.2016
 
Число     Длительность
опросов   всех опросов
  шт.       мсек
  2         0
  4         0 
  8         0
  16        0
  32        0
  64        0
  128       0
  256       1
  512       2
  1024      5
  2048      11
  4096      19
  9192      39
  16384     78
  32768     154

 */

Моя функция опроса ladyButton(номер_пина, исходное_состояние_контакта, число_чтений) получает три параметра и возвращает значение LOW/HIGH.

Как-то так.

По моей оценке на 255 запросов уходит около 1 мсек, а на 1024 запроса – 5 мсек. Лично я считаю, что информация из 1024 ответов надежнее, чем всего два ответа с интервалом 5 мсек.

Казалось бы, на этом можно закончить.

Но нахрена этот чел, подумаете вы, парил нам мозги своей суперпуперкнопкой, когда эта тема уже давно обсосана. И будете правы.

Но в действительности, все не так, как на самом деле L

Разных кнопок в мире гораздо больше, чем могут охватить наши форумы.

Например, в поливном хозяйстве у меня использованы контактные датчики уровня и датчики(реле) протока(потока). Это по сути своей те же самые кнопки, но с другими временнЫми параметрами срабатывания и механизмами "нажатия".

При заполнении бака сверху поплавок датчика уровня бултыхается на взволнованной поверхности воды, из-за чего насос может отключиться раньше времени. Или, что хуже, будет некоторое время кратковременно включаться/выключаться.

Другой живой пример. Контакты реле протока перестанут дергаться и будут надежно замкнуты, когда при заполнении трубы все пузырьки и водяные снаряды – есть такой инженерный термин снарядное течение - уже пронеслись и сплошной поток идет полным сечением трубы.

И пока такие реальные переходные процессы не успокоятся, моя система может ничего не делать и тупо ждать несколько секунд или даже десятков секунд до окончательного срабатывания датчика уровня и/или реле протока.

Вот для чего могут понадобиться другие алгоритмы сглаживания/фильтрации/демпфирования сигналов состояния кнопок.

Удачи всем!