Arduino.ru

Решил тоже небольшой этюд написать.
При разборке одного большого проекта, освоил работу с дисплеем LCD 1602 на контроллере HD44780 и выяснил интересную вещь. Хотя LCD 1602 может отображать только 2 строки по 16 символов, но в контроллере HD44780 память заложена на 2 строки по 40 символов. И в эту память можно выводить символы. А отобразить выведенные данные можно с помощью команд сдвига экрана (в библиотеке LiquidCrystal они называются scrollDisplayLeft и scrollDisplayRight). При этом сдвигаются обе строки экрана.
Для демонстрации решил вывести большие двухстрочные цифры. Так и появился нижеприведенный скетч.

#include <LiquidCrystal.h>

LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
 
char number[10][2][4] = {
  "\1\2\1", "\1\3\1",
  "\2\1 ",  "\3\1\3",
  "\2\4\1", "\1\5\3",
  "\2\4\1", "\3\5\1",
  "\1 \1",  "\2\2\1",
  "\1\4\2", "\3\5\1",
  "\1\4\2", "\1\5\1",
  "\2\4\1", " \1 ",
  "\1\4\1", "\1\5\1",
  "\1\4\1", "\3\5\1"  };
byte i;

void setup()
{
  byte pillar[8] = { 0x1F, 0x1F, 0x1F, 0x1F, 0x1F, 0x1F, 0x1F, 0x1F };
  byte upper1[8] = { 0x1F, 0x1F, 0x1F, 0x00, 0x00, 0x00, 0x00, 0x00 };
  byte lower1[8] = { 0x00, 0x00, 0x00, 0x00, 0x00, 0x1F, 0x1F, 0x1F };
  byte upper2[8] = { 0x1F, 0x1F, 0x1F, 0x00, 0x00, 0x00, 0x00, 0x1F };
  byte lower2[8] = { 0x1F, 0x00, 0x00, 0x00, 0x00, 0x1F, 0x1F, 0x1F };

  lcd.begin(16, 2);
  lcd.noCursor();

  lcd.createChar(1, pillar);
  lcd.createChar(2, upper1);
  lcd.createChar(3, lower1);
  lcd.createChar(4, upper2);
  lcd.createChar(5, lower2);

  for (i=0; i<=9; i++) {
    numprint(i, 4*i);
  }
  delay(2000);
}
 
void loop()
{
  for (i=0; i<40; i++) {
    lcd.scrollDisplayLeft();
    delay(1000);
  }

  for (i=0; i<16; i++) {
    lcd.scrollDisplayLeft();
  }
  delay(5000);

  for (i=0; i<8; i++) {
    lcd.scrollDisplayLeft();
  }
  delay(5000);

  for (i=0; i<16; i++) {
    lcd.scrollDisplayRight();
  }
  delay(5000);

  for (i=0; i<8; i++) {
    lcd.scrollDisplayRight();
  }
  delay(5000);
}

void numprint(byte num, byte poz)
{
  lcd.setCursor(poz, 0);
  lcd.print(number[num][0]);
  lcd.setCursor(poz, 1);
  lcd.print(number[num][1]);
}

Успехов в использовании данной возможности!