Милые шалости тернарного оператора

Войдите на сайт для отправки комментариев

120 ответов [Последнее сообщение]

Чт, 08/04/2021 - 16:27

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Вчера на амперке всплыла тема про тернарный оператор. ТС ничтоже сумнящеся заявил, что

код
расечатать ?
1 sig = <условие> ? <выражение 1> : <выражение 2>;
2
3 // И
4
5 if (<условие>) {
6 sig = <выражение 1>;
7 } else {
8 sig = <выражение 2>;
9 }

это одно и то же.

Подобного рода заявления встречались и у нас. Я обычно шутил насчёт того, что тернарный оператор открывает широкие возможности для настоящих мужчин (не зря его мисрасты не любят) и на этом ограничивался. А тут вдруг по дискуссии на амперке понял, что многие и вправду не понимают моих шуток и считают, что вышеприведённые конструкции действительно идентичны. Наверное, каждый из вас в своей профессии иногда с удивлением ловил себя на мысли, что оказывается «есть совсем простые вещи, которых неспециалисты не знают»! Вот и я себя поймал на этом. Захотелось исправить ситуацию и рассказать про тернарный оператор. Кто всё это знает – от них не убудет, но уверен, что многие не знают или знают не всё.

Сразу скажу, что приведённые выше куски кода не эквивалентны. Они эквивалентны лишь в частном случае, когда типы <выражения 1> и <выражения 2> в точности совпадают. Если же типы <выражения 1> и <выражения 2> различны, то ... там как раз открывается простор для творчества. Можно такого ~~наговноко...~~ (простите) натрюкачить, что хрен потом эту ошибку найдёшь!

Изложение построим так. Сначала я кратко поясняю, что происходит, когда эти выражения имеют различные типы и покажу два безобидных примера, демонстрирующих сказанное. Затем, покажу третий пример, в котором из-за этих особенностей программа просто не компилируется. Потом перейдём к более «вонючим» вещам. Четвёртый пример позволяет подобраться вплотную к болоту и ощутить его запах, а уж в пятом примере мы окунёмся в это болото с головой. Ну, и в конце я скажу пару слов «в защиту детёныша».

Итак, если типы <выражения 1> и <выражения 2> различны, компилятор пытается подобрать ближайший общий тип к которому можно преобразовать и то, и другое. Тип он подбирает по общим правилам преобразования типов (несколько страниц в стандарте), а если не может подобрать общий тип, то ругается и прекращает компиляцию.

Давайте посмотрим как это работает.

Пример №1

01// Пример граблей оператора ? №1
02//
03// Две функции ниже всегда возвращают true и false соответственно
04// Но неочевидным для компилятора образом, чтобы он не выбросил 
05// проверку при оптимизации
06inline bool cTrue(void) { return digitalRead(2) <= 1; }
07inline bool cFalse(void) { return digitalRead(2) > 1; }
08 
09//
10void setup() {
11    char c = 'A';
12    byte b = 48;
13    Serial.begin(9600);
14    //
15    Serial.println("При использовании if");
16    if (cTrue()) Serial.print(c); else Serial.print(b);
17    Serial.print(' ');
18    if (cFalse()) Serial.println(c); else Serial.println(b);
19    //
20    Serial.println("При использовании ?");
21    Serial.print( cTrue() ? c : b );
22    Serial.print(' ');
23    Serial.println( cFalse() ? c : b );
24}   
25void loop(void) {}
26 
27////////////////////////////
28//
29//      РЕЗУЛЬТАТ
30//
31//      При использовании if
32//      A 48
33//      При использовании ?
34//      65 48
35//

Здесь <выражение 1> и <выражение 2> имеют типы char и byte соответственно. Serial.print понимает и то, и другое, но печатает их по-разному - char - как символ, а byte - как число. Обратите внимание, что в варианте с if всё именно так и напечатано. А в варианте с ? оба значение напечатаны как числа, т.е. компилятор привёл из оба к типу byte, как к более общему. Т.е. мы уже видим, что программа ведёт себя по-разному при использовании if и при использовании ?.

Пример №2

01// Пример граблей оператора ? №2
02//
03// Две функции ниже всегда возвращают true и false соответственно
04// Но неочевидным для компилятора образом, чтобы он не выбросил 
05// проверку при оптимизации
06inline bool cTrue(void) { return digitalRead(2) <= 1; }
07inline bool cFalse(void) { return digitalRead(2) > 1; }
08 
09//
10void setup() {
11    int i = 22;
12    double d = M_PI;
13    Serial.begin(9600);
14    //
15    Serial.println("При использовании if");
16    if (cTrue()) Serial.print(i); else Serial.print(d);
17    Serial.print(' ');
18    if (cFalse()) Serial.println(i); else Serial.println(d);
19    //
20    Serial.println("При использовании ?");
21    Serial.print( cTrue() ? i : d );
22    Serial.print(' ');
23    Serial.println( cFalse() ? i : d );
24}   
25void loop(void) {}
26 
27////////////////////////////
28//
29//      РЕЗУЛЬТАТ
30//
31//      При использовании if
32//      22 3.14
33//      При использовании ?
34//      22.00 3.14
35//

Приблизительно тоже самое, только с типами int и double. При использовании if они так и печатаются как int и double, а вот при использовании ? - они оба печатаются как double, т.е. компилятор привёл оба значения к типу double.

Иногда бывает так, что сами по себе <выражение 1> и <выражение 2> оба вполне себе подходят для конечного результата, но не могут быть преобразованы к общему типу. В этом случае имеем ошибку компиляции, хотя «эквивалентная» конструкция с if вполне работает. Об этом третий пример:

01// Пример граблей оператора ? №3
02//
03//  Считаем, что мы что-то вычисляли и решение попало в переменную res
04//  При этом если res равно 0 - это значит, что решение не найдено
05//  Напечатаем результат
06//
07void setup() {
08    Serial.begin(9600);
09    //
10    int res = 1;
11    //
12    Serial.println("При использовании if");
13    if (res) Serial.println(res); else Serial.println("Решение не найдено");
14    //
15    Serial.println("При использовании ?");
16    Serial.print( res ? res : "Решение не найдено" );
17}   
18void loop(void) {}

Ну, что , компилятор не нашёл такого общего типа, к которому он мог бы преобразовать и const char * и int. Потому он обругал нас и сказал "сами разбирайтесь". Хотя, если бы он ничего не преобразовывал, то print-то вполне был готов скушать хоть const char *, хоть int, что мы и видим в варианте с if - там всё отлично работает.

Для тех, кому уже не терпится спросить: «И что? Это и всё веселье?» пора сказать – нет господа! Веселье ещё и не начиналось! Веселье начинается когда мы начинаем использовать свои собственные типы данных, а не простейшие встроенные типы, как мы делали до сих пор.

Наш четвёртый пример мало отличается от предыдущих, но в нём мы определим свой тип – комплексное число и попробуем в if и в ? напечатать либо его, либо обычное число с плавающей точкой.

01// Пример граблей оператора ? №4
02//
03// Две функции ниже всегда возвращают true и false соответственно
04// Но неочевидным для компилятора образом, чтобы он не выбросил 
05// проверку при оптимизации
06inline bool cTrue(void) { return digitalRead(2) <= 1; }
07inline bool cFalse(void) { return digitalRead(2) > 1; }
08 
09class Complex : public Printable {
10    double real;
11    double imaginary;
12public:
13    Complex(const double & r, const double i = 0) { real = r; imaginary = i; }
14    size_t printTo(Print& p) const {
15        size_t res = p.print('(');
16        res += p.print(real);
17        res += p.print('+');
18        res += p.print(imaginary);
19        res += p.print("i)");
20        return res;
21    }
22};
23 
24//
25void setup() {
26    Complex c(5, 7);
27    double d = M_PI;
28    Serial.begin(9600);
29    //
30    Serial.println("При использовании if");
31    if (cTrue()) Serial.print(c); else Serial.print(d);
32    Serial.print(' ');
33    if (cFalse()) Serial.println(c); else Serial.println(d);
34    //
35    Serial.println("При использовании ?");
36    Serial.print( cTrue() ? c : d );
37    Serial.print(' ');
38    Serial.println( cFalse() ? c : d );
39}   
40void loop(void) {}
41 
42////////////////////////////
43//
44//      РЕЗУЛЬТАТ
45//
46//      При использовании if
47//      (5.00+7.00i) 3.14
48//      При использовании ?
49//      (5.00+7.00i) (3.14+0.00i)
50//

Вроде, ничего особенного. В случае ? оба числа напечатались как комплексные, что вполне ожидаемо после первых двух примеров. Но тут есть нюанс! Чтобы преобразовать число в комплексное был вызван конструктор класса! А конструктор – это же уже программа! У неё могут быть побочные эффекты и вообще, там много чего может быть.

Вот давайте и посмотрим на более продвинутый пример с конструктором. В пятом примере мы пытаемся создать экземпляр класса String. Как дисциплинированные люди, мы проверяем создался ли экземпляр или для него памяти не хватило. Если создался, то печатаем его, а если не создался, то печатаем сообщение об ошибке. Сообщение – обычная строка – массив символов. Для имитации того, что нам не хватает памяти, мы специально загадим её настолько, чтобы строка уже не создалась и посмотрим, что получится. Итак, пример №5

01// Пример граблей оператора ? №5
02//
03 
04// Функция возвращает размер свободной памяти
05static inline size_t freeMemory(void) { 
06    extern char *__brkval;
07    return (__malloc_heap_end ? (size_t)__malloc_heap_end : SP - __malloc_margin) - 
08        (size_t)(__brkval ? __brkval : __malloc_heap_start); 
09}
10 
11void setup() {
12    Serial.begin(9600);
13    //
14    // Загадим память так, чтобы на строку Пи уже не хватило места
15    const size_t memSize = freeMemory() - 10;
16    memset(malloc(memSize),0 , memSize);
17 
18    // Теперь создаём строку и в случае успеха печатаем её, 
19    // а в случае неуспеха - сообщение о нехватке памяти
20    String s = String(M_PI, 6);
21 
22    Serial.println("При использовании if");
23    if (s) Serial.println(s); else Serial.println("No memory for string");
24 
25    Serial.println("При использовании ?");
26    Serial.flush(); // подождём пока всё выведется
27    Serial.println( s ? s : "No memory for string" );
28}
29 
30void loop(void) {}
31 
32////////////////////////////
33//
34//      РЕЗУЛЬТАТ
35//
36//      При использовании if
37//      No memory for string
38//      При использовании ?
39//
40//

Как видите с if всё работает! А вот с ? программа зависла! Почему? Ну, понятно, в случае с ? компилятор стал преобразовывать оба выражения тернарного оператора к общему типу. Таковым общим типом является String. Вот он и попытался создать String из нашего сообщения об ошибке! Но ведь на создание String у нас уже нет памяти! Здрасьте, приехали – подвисли :-(

Ну, как? Весело искать такую ошибку, особенно если она не в рафинированном примере,сделанном специально для её демонстрации, а в коде на пару тысяч строк?

И это "мы только зашли туда, чтобы потом всем говорить, что побывали в Лабиринте"! Там чем дальше в лес, тем толще партизаны! А какой простор для творчества предоставляет использование тернарного оператора с автоматическими типами? А с лямбдами? Там такие возможности говнокодерства открываются - куда там жалкому goto! По творческому потенциалу тернарный оператор можно сравнить разве что с #define.

В общем, тернарный оператор - вещь совсем «не для девочек». Ну, а поскольку программисты - в основном девочки (братья Стругацкие врать не станут), то, например MISRA попросту запретила использование этого оператора наравне с тем же goto.

Теперь обещанная пара слов «в защиту детёныша».

В простых случаях типа чисел одного типа, тернарный оператор выглядит очень компактно и понятно. Также есть достаточно мест, где применим только он и никакими if'ами его не заменишь. Это и условная инициализация ссылок, и условная инициализация членов класса в заголовке конструктора и другое.

Дополнение по результата обсуждения

Мне справедливо указали на отсутствие примера, показывающего работа именно с оператором присваивания (с чего начиналась статья).

Вот пример:

01// Пример граблей оператора ? №6
02 
03//  Класс Цитата
04struct Quotation : public Printable {
05    String m_text;
06    Quotation(void) { m_text = "<empty>"; }
07    Quotation(const Quotation & s) { m_text = s.m_text; }
08    size_t printTo(Print& p) const { return p.print(m_text); }
09};
10 
11//  Класс "Библия", наследник "Цитата"
12struct Bible : public Quotation{
13    Bible(const char * s = "") { m_text = s; }
14};
15 
16//  Класс "Феня", хранит цитату в двух видах. 
17// В каноническом и на фене. Везде использует
18// вариант на фене, но при преобразовании в 
19//  Bible выдаёт каноническую версию, а то неприлично
20struct Fenya : public Quotation {
21    String m_canonic;
22    Fenya(const char * t, const char * c) : m_canonic(c) { m_text = t; }
23    operator Bible(void) { return Bible(m_canonic.begin()); }
24};
25 
26Bible bq("\"Идущий за мной сильнее меня\" (Мат. 3:11)");
27 
28Fenya fq("\"Всякому взбрыкнувшему, да отбрыкнется, ибо нех!\" (Мк 4:24)",
29    "\"Какой мерой вы мерите, той и Бог вам отмерит и прибавит еще\" (Мк 4:24)");
30 
31//
32// Две функции ниже всегда возвращают true и false соответственно
33// Но неочевидным для компилятора образом, чтобы он не выбросил 
34// проверку при оптимизации с дуру
35inline bool cTrue(void) { return digitalRead(2) <= 1; }
36inline bool cFalse(void) { return digitalRead(2) > 1; }
37 
38//
39void setup() {
40    Serial.begin(9600);
41     
42    Quotation q2 = cTrue() ? bq : fq;
43    Quotation q3 = cFalse() ? bq : fq;
44    Serial.println("При использовании ?");
45    Serial.println(q2);
46    Serial.println(q3);
47    Serial.println();
48    //
49    Quotation q0, q1;
50    if (cTrue()) q0 = bq; else q0 = fq;
51    if (cFalse()) q1 = bq; else q1 = fq;
52    Serial.println("При использовании if");
53    Serial.println(q0);
54    Serial.println(q1);
55}   
56void loop(void) {}
57 
58////////////////////////////
59//
60//      РЕЗУЛЬТАТ
61//
62//      При использовании ?
63//      "Идущий за мной сильнее меня" (Мат. 3:11)
64//      "Какой мерой вы мерите, той и Бог вам отмерит и прибавит еще" (Мк 4:24)
65//      
66//      При использовании if
67//      "Идущий за мной сильнее меня" (Мат. 3:11)
68//      "Всякому взбрыкнувшему, да отбрыкнется, ибо нех!" (Мк 4:24)
69//

Результаты с «if» и с «?», как видите, разные.

Но тут мне хотелось бы сделать дополнительные пояснения об операторе присваивания и ещё об одних граблях.

При выполнении оператора присваивания, сначала вычисляется его правая часть. И только потом левая. В нашем случае это означает, что операции преобразования <выражения 1> и <выражения 2> к единому типу будут происходить так, как было описано выше, без оглядки на тип выражения в левой части оператора присваивания! И только потом, будет сделана попытка привести получившийся в правой части «общий» тип к типу левой части.

Отсюда следует, что в принципе возможна ситуация, когда сами по себе <выражение 1> и <выражение 2> вполне могли бы быть приведены к типу левой части, а вот тот «общий» тип, к которому их преобразовали – уже не приводится. В этом случае получим ошибку компиляции.

Чт, 08/04/2021 - 17:58

andriano

Offline

Зарегистрирован: 20.06.2015

Евгений Петрович, при всем уважении, крайне разочарован. (((((((((((((

Вначале Вы объявили, что две конструкции не являются эквивалентными, но ни одного подтверждающего это утверждения примера не привели.

Имманентным атрибутом каждого из двух исходных выражений является оператор присваивания (sig = ), но ни в одном из пяти последующих примеров оператор присваивания не используется.

Другими словами, все это очень интересно (как и любой публикуемый Вами материал), но в данном случае, увы, иллюстрация исходного утверждения (о неэквивалентности конструкций, содержащих оператор присваивания) не приведено.

Чт, 08/04/2021 - 18:10

Upper

Offline

Зарегистрирован: 23.06.2020

					1

					sig = <условие> ? <выражение 1> : <выражение 2>;

2

					3

					// И

4

					5

					if (<условие>) {

					6

					   sig = <выражение 1>;

					7

					} else {

					8
   sig = <выражение 2>;

Соответствует:

sig = cTrue() ? Serial.print(c) : Serial.print(b);

if (cTrue()) sig =Serial.print(c);
else
sig = Serial.print(b);

А примеры объясняют несколько иное.

Чт, 08/04/2021 - 18:37

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

andriano пишет:

ни одного подтверждающего это утверждения примера не привели.

Вы правда так считаете?

Странно, что Вы не увидели что там совершенно неважно присваивание или нет, а примеры сразу с печатью - исключительно для укорочения кода.

крайне разочарован. (((((((((((((

Вам нужен пример с присваиванием?

Чт, 08/04/2021 - 18:38

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Upper пишет:

Соответствует:

А примеры объясняют несколько иное.

Это ложное утверждение.

Чт, 08/04/2021 - 18:46

Upper

Offline

Зарегистрирован: 23.06.2020

ЕвгенийП пишет:

Upper пишет:

Соответствует:

А примеры объясняют несколько иное.

Это ложное утверждение.

Одновременно оба утверждения быть ложными не могут. Или вы делаете логическое И ?

Чт, 08/04/2021 - 19:54

Logik

Offline

Зарегистрирован: 05.08.2014

Увидел

return digitalRead(2) <= 1;

И дальше смотреть не стал. Магические числа какие-то... Это ж кто так учил проверять результат digitalRead(2)? Архат может?

Смотри в доку!

Функция digitalRead()

digitalRead()

Описание

Функция считывает значение с заданного входа - HIGH или LOW.

Чт, 08/04/2021 - 20:03

wdrakula

Offline

Зарегистрирован: 15.03.2016

ЕвгенийП пишет:

Upper пишет:

Соответствует:

А примеры объясняют несколько иное.

Это ложное утверждение.

Женя! Я слышал историю про бисер и домашних животных. Что-то там не очень выходило. ;)

Я завидую твоему терпению, я бы уже начал матюгами щедро посыпать, а потом сердечное ведрами глотать.

Чт, 08/04/2021 - 20:32

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Upper пишет:

Одновременно оба утверждения быть ложными не могут. Или вы делаете логическое И ?

Ну, почему же не могут. Вы утверждали

1) что конструкции с if и с ? из первого поста эквивалентны - это ложно ибо они не эквиваленты

2) что мой текст демонстрирует другое - это тоже ложно ибо он именно это и демонстрирует.

Вы, что мне интересно.

Вот Сергей наехал на мою манеру изложения, на то, что я плохо подобрал иллюстрации и доказательства своей главной мысли. Он не в первый раз это делает. Я обычно как-то отгавкиваюсь (как в #3), но прислушиваюсь к нему потому, что обычно в его словах что-то есть :-) В правильности же самой главной мысли он не сомневался потому, что понимает, что она верная.

Вы же попытались объяснить мне, что главная мысль неверна (конструкции эквивалентны), а мои примеры совсем не про неё, а про что-то другое. Вот ответьте мне, Вы правда считаете, что я не понимаю о чём пишу? Или Вы решили меня потроллить, чтобы на слабо заставить сделать пример с присваиванием? Ответьте пожалуйста, а я Вам тогда приз выдам :-)

Чт, 08/04/2021 - 20:41

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

wdrakula пишет:

я бы уже начал матюгами щедро посыпать, а потом сердечное ведрами глотать.

Граф, ну ты же знаешь, я же завязал с холиварами.

Будет нормальный разговор, объясню ещё раз, покажу пример именно с присваиванием - их есть у меня, только я не стал приводить, т.к. он посложнее этих. Но вот andriano наехал, что присваивания нет :-( В какой-то мере он, наверное, прав. То, что Upper вообще ничего не понял и утверждает, что конструкции эквивалентны, как раз доказывает правоту andriano. Так я покажу и с голимым присваиванием, и объясню ещё раз (или andriano попрошу объяснить) мне не жалко.

Ну, а не будет нормального разговора - ты знаешь, как я поступаю ( и тебе так советую). Коротко, одноразово и никаких сердечных. А то и вообще молча, как с постом #6.

Чт, 08/04/2021 - 21:28

#10

Upper

Offline

Зарегистрирован: 23.06.2020

Поясню, что я имел в виду.

(Дальше идут мое субективное восприятие, т.е как я прочитал)

Автор говорит, что сейчас он покажет что следующие записи могут привести к разному результату

sig = <условие> ? <выражение 1> : <выражение 2>;

// И

if (<условие>) {

sig = <выражение 1>;

} else {

sig = <выражение 2>;

В качестве первого примера рассматривается

if (cTrue()) Serial.print(c); else Serial.print(b);

Тогда по условиям задачи

<условие> = (cTrue())

<выражение 1> = Serial.print(c)

<выражение 2> = Serial.print(b)

sig игнорируется

И проверять надо выражение

sig = <условие> ? <выражение 1> : <выражение 2>;

sig = (cTrue()) ? Serial.print(c) : Serial.print(b);

А в примере проверяют несколько иное.

Serial.print( cTrue() ? c : b );

Я причитал этот материал как и andriano.

"Другими словами, все это очень интересно (как и любой публикуемый Вами материал), но в данном случае, увы, иллюстрация исходного утверждения (о неэквивалентности конструкций, содержащих оператор присваивания) не приведено."

Чт, 08/04/2021 - 21:57

#11

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Upper,

ну если так, так почему же просто не попросить привести пример именно с присваиванием? Зачем Вы в посте №2 умничать начали про "несколько иное"?

Вот Вам чистый пример с присваиванием.

01// Пример граблей оператора ? №6
02 
03//  Класс Цитата
04struct Quotation : public Printable {
05    String m_text;
06    Quotation(void) { m_text = "<empty>"; }
07    Quotation(const Quotation & s) { m_text = s.m_text; }
08    size_t printTo(Print& p) const { return p.print(m_text); }
09};
10 
11//  Класс "Библия", наследник "Цитата"
12struct Bible : public Quotation{
13    Bible(const char * s = "") { m_text = s; }
14};
15 
16//  Класс "Феня", хранит цитату в двух видах. 
17// В каноническом и на фене. Везде использует
18// вариант на фене, но при преобразовании в 
19//  Bible выдаёт каноническую цитату, а то неприлично
20struct Fenya : public Quotation {
21    String m_canonic;
22    Fenya(const char * t, const char * c) : m_canonic(c) { m_text = t; }
23    operator Bible(void) { return Bible(m_canonic.begin()); }
24};
25 
26Bible bq("\"Идущий за мной сильнее меня\" (Мат. 3:11)");
27 
28Fenya fq("\"Всякому взбрыкнувшему, да отбрыкнется, ибо нех!\" (Мк 4:24)",
29    "\"Какой мерой вы мерите, той и Бог вам отмерит и прибавит еще\" (Мк 4:24)");
30 
31//
32// Две функции ниже всегда возвращают true и false сщщтветственно
33// Но неочевидным для компилятора образом, чтобы он выбросил 
34// проверку при оптимизации
35inline bool cTrue(void) { return digitalRead(2) <= 1; }
36inline bool cFalse(void) { return digitalRead(2) > 1; }
37 
38//
39void setup() {
40    Serial.begin(9600);
41     
42    Quotation q2 = cTrue() ? bq : fq;
43    Quotation q3 = cFalse() ? bq : fq;
44    Serial.println("При использовании ?");
45    Serial.println(q2);
46    Serial.println(q3);
47    Serial.println();
48    //
49    Quotation q0, q1;
50    if (cTrue()) q0 = bq; else q0 = fq;
51    if (cFalse()) q1 = bq; else q1 = fq;
52    Serial.println("При использовании if");
53    Serial.println(q0);
54    Serial.println(q1);
55}   
56void loop(void) {}
57 
58////////////////////////////
59//
60//      РЕЗУЛЬТАТ
61//
62//      При использовании ?
63//      "Идущий за мной сильнее меня" (Мат. 3:11)
64//      "Какой мерой вы мерите, той и Бог вам отмерит и прибавит еще" (Мк 4:24)
65//      
66//      При использовании if
67//      "Идущий за мной сильнее меня" (Мат. 3:11)
68//      "Всякому взбрыкнувшему, да отбрыкнется, ибо нех!" (Мк 4:24)
69//

Как видите, результаты получаются разные. Почему? Это написано в стартовом посте - он именно об этом, а вовсе не "несколько иное".

Изучайте разбирайтесь. А если непонятно - задавайте вопросы, а не ...

Чт, 08/04/2021 - 22:14

#12

brokly

Offline

Зарегистрирован: 08.02.2014

Я думаю самым лучшим доказательством не эквивалентности конструкций должен стать дизассемблированный код. Эквивалентные конструкции должны создать эквивалентный код. Очевидно, что компилятор использует различные шаблоны для этих конструкций.

И тут кроме как "Спасибо дядя Женя !", сказать нечего.

Чт, 08/04/2021 - 23:07

#13

andriano

Offline

Зарегистрирован: 20.06.2015

Красиво!

Еще раз убедился, что я не знаю Си++.

Вот в строке 23 используется метод begin() переменной типа String. А в документации по типу String я такого метода не нахожу: https://www.arduino.cc/reference/en/language/variables/data-types/stringobject/

И почему, скажем, не m_canonic.c_str()?

Чт, 08/04/2021 - 23:13

#14

BOOM

Offline

Зарегистрирован: 14.11.2018

Попкорн на исходе, но с удовольствием слежу!..))

Чт, 08/04/2021 - 23:16

#15

SergeiL

Offline

Зарегистрирован: 05.11.2018

Я бы сказал они были идентичны до того как Си перерос в С++.

Чт, 08/04/2021 - 23:20

#16

wdrakula

Offline

Зарегистрирован: 15.03.2016

andriano пишет:

Вот в строке 23 используется метод begin() переменной типа String. А в документации по типу String я такого метода не нахожу

Сереж! Прости плз, но вечер, литр самогона и все эти вещи. Это снова наезд или тебе лень открыть WString.h в коре ардуино ИДЕ?

Б..же! Где Женя берет столько терпения? Может пить нужно меньше? ...или больше? Но что-то делать точно надо!

Чт, 08/04/2021 - 23:27

#17

wdrakula

Offline

Зарегистрирован: 15.03.2016

SergeiL пишет:

Я бы сказал они были идентичны до того как Си перерос в С++.

..ля! Нет, это не так. Тернарный оператор ВЫНУЖДАЕТ компилятор приводить к общему типу альтернативы, а if() - нет. Вот и вся разница, из которой много чего можно получить.

Есть еще куча неочевидных особенностей компиляции.

Чт, 08/04/2021 - 23:48

#18

SergeiL

Offline

Зарегистрирован: 05.11.2018

wdrakula пишет:

SergeiL пишет:

Я бы сказал они были идентичны до того как Си перерос в С++.

Есть еще куча неочевидных особенностей компиляции.

А если справа от "?" одинаковые типы данных?

Я бы добавил, На Си в процедуре присвоения всегда должны были использоваться одни типы данных. Отсутствие указания типа, при неявном преобразовании могло внести ошибку, поэтому всегда использовалось явное указание.

Пт, 09/04/2021 - 00:04

#19

SergeiL

Offline

Зарегистрирован: 05.11.2018

brokly пишет:

И тут кроме как "Спасибо дядя Женя !", сказать нечего.

Я этим занимался в 80-ых - 90-ых. Разницы в ассемблере не увидел. Но это был компилятор из 80-ых.

Тогда писали свою ОС, я писал библиотеки Си для нашей ОС.

Пт, 09/04/2021 - 00:08

#20

andriano

Offline

Зарегистрирован: 20.06.2015

wdrakula пишет:

Это снова наезд или тебе лень открыть WString.h в коре ардуино ИДЕ?

В коре или в корне?

У меня в папке Ардуино 9 штук WString.h, причем ни одного из них - в корне. А что такое "в коре", я вообще не знаю.

И потом, зачем открывать какой-то файл (кстати, откуда я могу узнать, какой именно файл нужно открывать, если у меня в текущей версии этих файлов 21603 штуки?), если есть официальная документация?

Опять же, даже открыв указанный файл, я не понял, в чем отличие begin() от c_str(), т.к. не понял, для чего нужны одновременно buffer и wbuffer, не говоря о том, почему в данном случае нужен именно wbuffer.

PS. И, кстати, убедился, что "наезд" был обоснованным: из пяти примеров исходного поста темы никак простым способом не следует шестой, в котором используется присваивание.

Пт, 09/04/2021 - 00:24

#21

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

andriano пишет:

не m_canonic.c_str()?

Я забыл как он называется. Попробовал m_str - нету такого, полез в исходник - begin - первое, что увидел, что buffer возвращает. Конечно, пофиг какой юзать, лишь бы буфер вернул.

Пт, 09/04/2021 - 02:37

#22

b707

Offline

Зарегистрирован: 26.05.2017

ЕвгенийП пишет:

MISRA попросту запретила использование этого оператора наравне с тем же goto.

поддерживаю МИСРУ в обоих перечисленных случаях :)

Евгений, спасибо!

Пт, 09/04/2021 - 08:48

#23

ua6em

Offline

Зарегистрирован: 17.08.2016

пятница, слежу, продолжение будет?

Пт, 09/04/2021 - 08:55

#24

andriano

Offline

Зарегистрирован: 20.06.2015

ua6em пишет:

пятница, слежу, продолжение будет?

Я так понимаю, доклад окончен, и идет процесс ответов на вопросы.

Хотите продолжения - задавайте вопрос. Попросите, например, привести пример с присваиванием на Си.

Пт, 09/04/2021 - 10:37

#25

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

ua6em пишет:

продолжение будет?

В какой-то мере продолжение.

Пт, 09/04/2021 - 10:39

#26

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

andriano пишет:

Попросите, например, привести пример с присваиванием на Си.

Я, если честно, ожидал просьбы поподробнее раскрыть тему насчёт

ЕвгенийП пишет:

есть достаточно мест, где применим только он (тернарник) и никакими if'ами его не заменишь

Изначально я, кстати, хотел привести такие примеры, но под конец написания уже устал :-(

Пт, 09/04/2021 - 11:22

#27

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

И, да, забыл ответить про Си.

Там всё гораздо менее творчески :-( Вот что написано в ISO/IEC 9899:2018, § 6.5.15.

One of the following shall hold for the second and third operands:
— both operands have arithmetic type;
— both operands have the same structure or union type;
— both operands have void type;
— both operands are pointers to qualifed or unqualifed versions of compatible types;
— one operand is a pointer and the other is a null pointer constant; or
— one operand is a pointer to an object type and the other is a pointer to a qualifed or unqualifed version of void.

Там, конечно, можно поиграть с квалификаторами (когда, например, ни с того ни с сего появляется const или volatile), но это очень тонкие вещи и эффектные примеры на них трудно сделать.

Пт, 09/04/2021 - 13:16

#28

vde69

Offline

Зарегистрирован: 10.01.2016

Евгению - спасибо.

Но в моем понимании главной проблемой на которую Евгений не акценитровал внимание новичков - это то, что здесь вопрос не в конструкциях а в контексте применения данных конструкция. Примеров можно приводить много (и из других операторов), но все это сводится к простому правилу:

надо писать просто и единообразно, уж если используем процедурный язык (а с++ это именно процедурный язык) то в нем не стоит использовать подходы из функциональных языков, и все эти "замыкания", и прочие спагетины как в условиях так и в любых других местах применения это вред...

Операторы должны быть простыми.... Особенно для новичков...

зы

если чего, я несколько лет программировал на AutiLisp, и знаю толк в извращениях :)

Пт, 09/04/2021 - 13:22

#29

wdrakula

Offline

Зарегистрирован: 15.03.2016

andriano пишет:

Хотите продолжения - задавайте вопрос. Попросите, например, привести пример с присваиванием на Си.

Пример ЧИСТО с присваиванием. Женя, позволишь?

Наслаждаемся. Я специально сделал случайные числа, чтобы иногда было одинаково, а иногда нет. Запускать на Нано.

Очень "приятно" подобную ошибку искать в релизе ;)))))))).

01const  int16_t Modulo = 1000;
02 
03template<typename T>
04T mod (T a, int16_t b) {
05  T x = a % b;
06  if (x < 0) return x + b;
07  return x;
08}
09 
10int Wprintf(const char* __fmt, ...) {
11  char s[64];
12  va_list ap;
13  va_start(ap, __fmt);
14  vsnprintf(s, 64, __fmt, ap);
15  va_end(ap);
16  Serial.print(s);
17}
18 
19void setup() {
20  Serial.begin(115200);
21}
22 
23void loop() {
24  int16_t x = random(Modulo);
25  int16_t y = random(Modulo);
26 
27  uint16_t ux = x;
28  uint16_t uy = y;
29 
30  int rIF, rTER;
31 
32  if (x < y) rIF = mod((x - y), Modulo) ;
33  else rIF = mod((uy - ux), Modulo) ;
34 
35  rTER = mod((x < y) ? (x - y) : (uy - ux), Modulo);
36 
37  Wprintf ("if vs ()?():()===> %d %d\n", rIF, rTER);
38 
39  delay(1000);
40}

Пт, 09/04/2021 - 13:42

#30

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

vde69 пишет:

Операторы должны быть простыми.... Особенно для новичков...

В этой фразе есть противоречие. Очень часто новичок не понимает что на самом деле просто, а что сложно.

Пт, 09/04/2021 - 13:50

#31

wdrakula

Offline

Зарегистрирован: 15.03.2016

Женя! Просто как упражнение для ума. Измени ровно ОДНУ букву в моем примере, чтобы глюк пропал. Ну если интересно, конечно.

Пт, 09/04/2021 - 13:54

#32

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Граф, ты читер! :-)

Пт, 09/04/2021 - 13:57

#33

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

wdrakula пишет:

Измени ровно ОДНУ букву

Ты, видимо имел в виду не изменить, а добавить. Букву "u" если точнее. В какое место её добавить колоться не буду - не один я тут :-)

Пт, 09/04/2021 - 14:22

#34

wdrakula

Offline

Зарегистрирован: 15.03.2016

ЕвгенийП пишет:

wdrakula пишет:

Измени ровно ОДНУ букву

Так точно! ;)) Сперва я написал без глюка, и потом пришлось как раз убирать эту "u", чтобы организовать глюк.

Пт, 09/04/2021 - 14:27

#35

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Граф, скажи лучше как тебе вот такая фраза из стандарта: Using a bool value in ways described by this document as “undefined”, such as by examining the value of an uninitialized automatic object, might cause it to behave as if it is neither true nor false.

Вот бы пример придумать! Я подумаю, кстати :-)

Пт, 09/04/2021 - 14:46

#36

vde69

Offline

Зарегистрирован: 10.01.2016

ЕвгенийП пишет:

wdrakula пишет:

Измени ровно ОДНУ букву

кстати я недавно попадал, когда наоброт была лишняя эта самая буква u :)

ну что-то типа

void i;

if ((boolean) i) {}

Пт, 09/04/2021 - 15:01

#37

DetSimen

Offline

Зарегистрирован: 25.01.2017

vde69 пишет:

ну что-то типа

void i;

ты точно понимаешь что пишешь?

Пт, 09/04/2021 - 15:21

#38

wdrakula

Offline

Зарегистрирован: 15.03.2016

ЕвгенийП пишет:

Вот бы пример придумать! Я подумаю, кстати :-)

Думаю... пока компилятор мертво стоит на том, чтобы не дать мне даже попробовать использовать не инициализированный автоматический объект. Думаю, как его наипать?

Пт, 09/04/2021 - 15:28

#39

vde69

Offline

Зарегистрирован: 10.01.2016

DetSimen пишет:

vde69 пишет:

ну что-то типа

void i;

ты точно понимаешь что пишешь?

так лучше? ну нет у меня на работе ничего для проверки синтаксиса :)

void* i;

if (*((boolean*) i)) {}

Сб, 10/04/2021 - 00:31

#40

andriano

Offline

Зарегистрирован: 20.06.2015

wdrakula пишет:

Наслаждаемся.

Оно, вроде, красиво, но:

1sketch_apr09a:4: error: 'T' does not name a type
2 
3 T mod (T a, int16_t b) {
4 
5 ^
6 
7exit status 1
8'T' does not name a type

Сб, 10/04/2021 - 07:32

#41

wdrakula

Offline

Зарегистрирован: 15.03.2016

Сережа! Будь внимательнее при копировании. Ты строчку template<> потерял. Это шаблон. Несколько неожиданно для тебя. За неделю уже вторая странность. Первая была с незнанием понятия "конечная точка".
________
ЗЫ: ты вот скажи: если у тебя появилась ошибка при компиляции, тебе не кажется, что нужно проверить себя в первую очередь??? И не позориться. Фу!

Сб, 10/04/2021 - 09:14

#42

Upper

Offline

Зарегистрирован: 23.06.2020

wdrakula пишет:

если тебе не кажется, что нужно проверить себя в первую очередь??? И не позориться. Фу!

Зафиксирую.

Сб, 10/04/2021 - 09:44

#43

andriano

Offline

Зарегистрирован: 20.06.2015

wdrakula пишет:

Сережа! Будь внимательнее при копировании. Ты строчку template<> потерял. Это шаблон. Несколько неожиданно для тебя. За неделю уже вторая странность. Первая была с незнанием понятия "конечная точка". ________ ЗЫ: ты вот скажи: если у тебя появилась ошибка при компиляции, тебе не кажется, что нужно проверить себя в первую очередь??? И не позориться. Фу!

Нет, Влад, не потерял я ее, просто компилятор приводит лишь тот фрагмент, в котором ошибка, а не весь код примера.

Для контроля только что скопировал код непосредственно из окна своей IDE:

01const  int16_t Modulo = 1000;
02 
03template<typename T>
04T mod (T a, int16_t b) {
05  T x = a % b;
06  if (x < 0) return x + b;
07  return x;
08}
09 
10int Wprintf(const char* __fmt, ...) {
11  char s[64];
12  va_list ap;
13  va_start(ap, __fmt);
14  vsnprintf(s, 64, __fmt, ap);
15  va_end(ap);
16  Serial.print(s);
17}
18 
19void setup() {
20  Serial.begin(115200);
21}
22 
23void loop() {
24  int16_t x = random(Modulo);
25  int16_t y = random(Modulo);
26 
27  uint16_t ux = x;
28  uint16_t uy = y;
29 
30  int rIF, rTER;
31 
32  if (x < y) rIF = mod((x - y), Modulo) ;
33  else rIF = mod((uy - ux), Modulo) ;
34 
35  rTER = mod((x < y) ? (x - y) : (uy - ux), Modulo);
36 
37  Wprintf ("if vs ()?():()===> %d %d\n", rIF, rTER);
38 
39  delay(1000);
40}

Сб, 10/04/2021 - 10:14

#44

wdrakula

Offline

Зарегистрирован: 15.03.2016

Сережа! Ну проверь себя. Ну пожалуйста!!! Все работает в штатной ИДЕ 1.8.13. Форум попросить помочь скомпилировать??? Ну блин! Я никогда не публикую код, не запустив. Ты просто оскорбляешь меня, прости за резкость.

Сб, 10/04/2021 - 10:34

#45

wdrakula

Offline

Зарегистрирован: 15.03.2016

Я только что вставил себе в ИДЕ то, что ты опубликовал. Всё, естественно собирается. И проверить это может ЛЮБОЙ находящийся на форуме.

Давай попробуем разобраться. Какая выбрана плата? Какая версия ИДЕ? Не менял ли ты настройки у себя? А ты случайно файл не назвал с расширением ".c", потому что в С нет темплейтов?

========================

Вот видео с записью с моего экрана прямо сейчас. Сергей! Твое поведение - недопустимо!!!!!!!!!!!!!!!!!!!!!!!!!!!

https://youtu.be/1L7wh1Vc3Do

Сб, 10/04/2021 - 10:53

#46

wdrakula

Offline

Зарегистрирован: 15.03.2016

Коллеги! Очень прошу тех, у кого есть возможность проверить и отписаться! Для меня это ПРИНЦИПИАЛЬНЫЙ вопрос. Меня Андриано обвинил в подлоге, прошу откомпилировать и запустить код даже не из моего, а из его поста!

Я собирал на Нано, Мега, Леонардо. ESP8266 и ESP32. Для ESP32 нужно добавить return в функцмю wprintf, там по умолчанию жесткая проверка возвращаемых типов. Для остальных плат ничего добавлять не надо.

Везде собирается, на 32-битных нет "глюка", понятно почему, если не понятно, объясню я или Женя позже. Сейчас же мне важно разобраться с обвинениями.

Сб, 10/04/2021 - 10:57

#47

Green

Offline

Зарегистрирован: 01.10.2015

Нано, компилируется, запускается.

01if vs ()?():()===> 878 878
02if vs ()?():()===> 666 202
03if vs ()?():()===> 322 322
04if vs ()?():()===> 261 261
05if vs ()?():()===> 86 86
06if vs ()?():()===> 52 52
07if vs ()?():()===> 598 134
08if vs ()?():()===> 308 308
09if vs ()?():()===> 402 402
10if vs ()?():()===> 984 984
11if vs ()?():()===> 627 163
12if vs ()?():()===> 821 357
13if vs ()?():()===> 55 55
14if vs ()?():()===> 271 807
15if vs ()?():()===> 291 291
16if vs ()?():()===> 359 359
17if vs ()?():()===> 706 706
18if vs ()?():()===> 758 294
19if vs ()?():()===> 241 241
20if vs ()?():()===> 479 479
21if vs ()?():()===> 740 276
22if vs ()?():()===> 399 399
23if vs ()?():()===> 837 373
24if vs ()?():()===> 848 384
25if vs ()?():()===> 764 300

Сб, 10/04/2021 - 11:05

#48

ЕвгенийП

Offline

Зарегистрирован: 25.05.2015

Граф, думаю, andriano тебя тебя троллит. Посмотри внимательно на #29 - вот чует моё сердце, что он твой темплэйт на Си компилирует.

Сб, 10/04/2021 - 11:05

#49

wdrakula

Offline

Зарегистрирован: 15.03.2016

Green! Спасибо!

Сб, 10/04/2021 - 11:12

#50

wdrakula

Offline

Зарегистрирован: 15.03.2016

ЕвгенийП пишет:

"Андриано" в курсе, что обвинения во лжи моё больное место. Я с 6 утра уже не сплю и глотаю бета-блокаторы!!!!! Если ты прав - так еще хуже! Тогда это просто ..дство! ...слов нет! ...сорри!

С++ темплейт там не принципиален, как любой понимает. Можно просто "%" оставить, будет еще нагляднее. Темплейт - украшательство, исправляющее дурь авторов стандарта, по которой "%" может давать отрицательные значения. (в половине ЯП, а в другой (например в Питоне) математики победили).

Arduino.ru

Регистрация новых пользователей и создание новых тем теперь только на новом форуме https://forum.arduino.ru