Arduino.ru

ИМХО. Зачем использовать дополнительные библиотеки когда стандартными можно обойтись. Зачем вам посредники!

#include "Wire.h"
#define DS1307_I2C_ADDRESS 0x68


byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}


byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}

void setDateDs1307(byte second,        // 0-59
                   byte minute,        // 0-59
                   byte hour)          // 0-99
{
   Wire.beginTransmission(DS1307_I2C_ADDRESS);
   Wire.write(0);
   Wire.write(decToBcd(second));    
   Wire.write(decToBcd(minute));
   Wire.write(decToBcd(hour));     
   Wire.endTransmission();
}


void getDateDs1307(byte *second,
          byte *minute,
          byte *hour)
{

  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.write(0);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 3);

  *second     = bcdToDec(Wire.read());
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read());  
}

void setup()
{
  byte second, minute, hour;
  Wire.begin();
  Serial.begin(9600);

  second = 45;
  minute = 3;
  hour = 7;

  setDateDs1307(second, minute, hour);
}

void loop()
{
  byte second, minute, hour;

  getDateDs1307(&second, &minute, &hour);
  Serial.print(hour, DEC);
  Serial.print(":");
  Serial.print(minute, DEC);
  Serial.print(":");
  Serial.println(second, DEC);


  delay(1000);
}

Сохранил себе в "полезняшки" :) Спасибо.

Там код чтобы время изымать. А есть дополнение чтобы и дату знать.
А можешь поделиться полезняками)))) levvarr собака ya.ru
 

Увы, вынужден расстроить :( Идея собирания полезняшек пришла только что, и кроме Вашей там пока ничего нет. Но на будущее - буду иметь в виду. Поделюсь :)

 Осталось только оформить эту полезняшку в виде библиотеки, для большего удобства повторного использованияи... "Зачем вам посредники!"

;)

Библиотека же, от "просто функции скопировать в скетч" отличается только "удобством использования". Что-бы не засорять собственный скетч вспомогательными функциями. Да и, если скетчей много, не приходилось, если затесалась ошибка, бегать потом по 10-ти местам и везде вносить поправку.

Вообщем библиотеки и возникли для реализации потребности "повторно использовать код". Так что "полезняшки" нужно хранить в виде библиотек :) Copy-paste - зло.

Согласен. Но библиотека подразумевает нечто большее, чем работающий кусок кода... Как минимум, хорошее описание, функциональный обхват... Будет время - сделаю библу, а пока пускай так полежит :)

Вот ссылка на DS1307 для 1.0:
http://arduino.cc/forum/index.php?topic=93077.0
 

LEVV2006, а можно в вашем примере сделать функции чтения/записи даты и дня недели?

Еще объясниет мне, каким образом назначается адрес:

#define DS1307_I2C_ADDRESS 0x68

Да можно. Надо посмотреть дома.

Про адрес: я этот код сам откуда то взял. Этот адрес по-моему стандартный для всех часов. По крайней мере я использовал этот код во всех часах и всё нормально работало. 

Вот!!! Часы + календарь

#include "Wire.h"
#define DS1307_I2C_ADDRESS 0x68

byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}

byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}

void setDateDs1307(byte second,        // 0-59
                   byte minute,        // 0-59
                   byte hour,          // 1-23
                   byte dayOfWeek,     // 1-7
                   byte dayOfMonth,    // 1-28/29/30/31
                   byte month,         // 1-12
                   byte year)          // 0-99
{
   Wire.beginTransmission(DS1307_I2C_ADDRESS);
   Wire.write(0);
   Wire.write(decToBcd(second));    
   Wire.write(decToBcd(minute));
   Wire.write(decToBcd(hour));     
   Wire.write(decToBcd(dayOfWeek));
   Wire.write(decToBcd(dayOfMonth));
   Wire.write(decToBcd(month));
   Wire.write(decToBcd(year));
   Wire.endTransmission();
}

void getDateDs1307(byte *second,
          byte *minute,
          byte *hour,
          byte *dayOfWeek,
          byte *dayOfMonth,
          byte *month,
          byte *year)
{

  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.write(0);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 7);

  *second     = bcdToDec(Wire.read() & 0x7f);
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read() & 0x3f); 
  *dayOfWeek  = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month      = bcdToDec(Wire.read());
  *year       = bcdToDec(Wire.read());
}

void setup()
{
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
  Wire.begin();
  Serial.begin(9600);

  second = 45;
  minute = 3;
  hour = 7;
  dayOfWeek = 5;
  dayOfMonth = 17;
  month = 4;
  year = 8;
  setDateDs1307(second, minute, hour, dayOfWeek, dayOfMonth, month, year);
}

void loop()
{
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;

  getDateDs1307(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month, &year);
  Serial.print(hour, DEC);
  Serial.print(":");
  Serial.print(minute, DEC);
  Serial.print(":");
  Serial.print(second, DEC);
  Serial.print("  ");
  Serial.print(month, DEC);
  Serial.print("/");
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  Serial.print(year, DEC);
  Serial.print("  Day_of_week:");
  Serial.println(dayOfWeek, DEC);

  delay(1000);
}

LEVV2006, спасибо. А как Ваш код изменить для использования с мега? (SDA, SCL соответственно на 20, 21 пинах)?

У меня меги нет. Так что я не знаю как для неё нужно писать код. Возможно нужно подключить библиотеку Wire.h. для меги

LEVV2006, спасибо

LEVV2006, похоже, ничего в коде менять не надо - компилятор и так все слопал. Но на выходе получаю вот такие значения:

Быстрый поиск результатов. Не дал результата но у меня дома есть где то в закладках как работают эти часы.

Пока так

1)      вы должны проверить правильность подключения микросхемы по даташиту.

2)      Если на отдельном модуле работает нормально а на плате нет. То скорее всего немного неправильный код.

3)      Я точно помню что в часах есть управляющий бит отвечающий за пуск и остановку счётчика времени.

Зы. Я тоже получал такие значения при неправильном подключении кажется (не судите строга я с часами больше 8 месяцев назад имел дело и сейчас многих деталей не помню)

ps http://avrdevices.ru/chasi-realynogo-vremeni-ds1307/

Так... вот что удалось выяснить.

1. модуль часов распаян на плате верно (заводская плата, но все равно проверил разводку и убедился, что все правильно)

2. когда батарейки резервной нет часы показывают установленное время и стоят (вполне ожидаемо)

3. когда резервная батарейка стоит, часы дают время-дату: 45:165:85  165/165/165 и часы тоже стоят.

вот интересно, с чем это может быть связано? Если кварц "мертвый" - возможна такая "работа"?

еще прочитал про бит "запрет осцилляции"  (7й бит по адресу 0x0h) - по умолчанию он стоит в 1 (часы будут стоять), нужно поставить в "0"

Как это сделать?

Wire.beginTransmission(DS1307_I2C_ADDRESS);
Wire.write(0);
Wire.write(0x0h);    
Wire.write(0);
Wire.endTransmission();

Может быть так? Надо спросить у профессионалов на форуме!!!

этот кусок не компилируется даже. 

ошибка error: invalid suffix "h" on integer constant

нашел, в чем причина

оказалось, "железячная". Разработчики платы развели плату таким образом, что 8 нога от DS1307 (Vcc) идет на 3.3В

Таким образом, этот модуль вообще на плате НИКОГДА работать не будет (модуль включается на нормальный режим работы, когда напряжение на Vcc больше, чем 1.25*Vbat). Батарейка используется 3В

у меня была та же проблема. пока я не нашел другую библиотеку и не подключил часы к i2c на мене меге 20 и 21 нога. и все заработало. если надо, могу скинуть библ.

в данном случае проблема именно с питанием.

после того, как "оторвал" ножку 8 микросхемы DS1307 и не повесил ее на +5В (напомню, была на 3.3В разведена) - система не работала. 

Сейчас работает хорошо, но часы останавливаются, если отключить питание. Описание такой проблемы уже было и на этом форуме (предлагалось конденсатор по питанию этой микросхеме подключить - пробовал, не помогло.. еще предлагали посмотреть цепь сброса у микроконтроллера (подтяжка) - имеется, и все равно часы "встают").

Решение до конца не найдено, но часики тикают.

Можно вопрос почти в тему?...

Приобрел модуль RTC, на нем микросхема часов и еще одна. Как я понял это память чтоль еще? Зачем она вообще?

Как пишут китайцы: "56 байт слаболетучей памяти имеющеся к потребителю". Использовать - можно вместо eeprom для сохранения данных между перезагрузками, или при отключении питания ардуины. Мне сейчас тоже приехали две таких платы - буду изучать возможности... Про сам чип AT24C32AN-10SU-2.7 пишут, что он 32 килобайта (4096х8), и рассчитан на 1 миллион циклов записи и 100 лет хранения (сравним с встроенным eeprom и порадуемся).

Более вдумчивое чтение

http://robozone.su/info/10-ds1307-chasy-realnogo-vremeni-s.html

и

http://www.henningkarlsen.com/electronics/library.php?id=34

подсказывает, что 56 байт остается свободными в самой микросхеме DS1307, а вторая микруха - это чистые 32К памяти.

Питание: 5V (а не 3.3, как у китайцев на картинке нарисовано!), GND.

Подтягивающие резисторы уже есть на плате.

Пины для данных: (http://arduino.cc/en/Reference/Wire)

Сканируем программой i2c_scanner http://playground.arduino.cc//Main/I2cScanner

Scanning...
I2C device found at address 0x50 !
I2C device found at address 0x68 !
done

Это одна плата с двумя устройствами: часы и микросхема памяти...

С eeprom работает скетч: http://playground.arduino.cc/Code/I2CEEPROM.

Можете поподробнее разъяснить как работет скетч от LEVV2006, а именно функция getDateDs1307

void getDateDs1307(byte *second,
          byte *minute,
          byte *hour)
{

  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.write(0);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 3);

  *second     = bcdToDec(Wire.read());
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read());  
}

getDateDs1307(&second, &minute, &hour);

Как я понял в нее передаются номера ячеек пямяти переменных second, minute, hour, затем считывается три байта из памяти ds1307 и  Wire.read записывает в соответствующие номерам переменные текущее время.

Я хочу запрашивать только минуты и часы (секунды не нужны), если убрать строки "byte *second" и "*second = bcdToDec(Wire.read());", то в hour записываются минуты, а в minute секунды.

Как можно запрашивать только второй и третий байт из ds1307?

Да никак. Просто читаете первый байт впустую, а затем читаете минуты и часы

   Wire.read();
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read()); 

Добавил день, дату, месяц, год.  Может кому надо будет. 

#include "Wire.h"
#define DS1307_I2C_ADDRESS 0x68


byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}


byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}


void setDateDs1307(byte second,        // 0-59
                   byte minute,        // 0-59
                   byte hour,
                   byte day,
                   byte date,
                   byte month,
                   byte year)          // 0-99
{
   Wire.beginTransmission(DS1307_I2C_ADDRESS);
   Wire.write(0);
   Wire.write(decToBcd(second));    
   Wire.write(decToBcd(minute));
   Wire.write(decToBcd(hour));
   Wire.write(decToBcd(day));  
   Wire.write(decToBcd(date));
   Wire.write(decToBcd(month));  
   Wire.write(decToBcd(year));   
   Wire.endTransmission();
}


void getDateDs1307(byte *second,
          byte *minute,
          byte *hour,
          byte *day,
          byte *date,
          byte *month,
          byte *year)
{

  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.write(0);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 7);

  *second     = bcdToDec(Wire.read());
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read());  
  *day        = bcdToDec(Wire.read());
  *date       = bcdToDec(Wire.read());
  *month      = bcdToDec(Wire.read());
  *year       = bcdToDec(Wire.read());
}

void setup()
{
  byte second, minute, hour, day, date, month, year;
  Wire.begin();
  Serial.begin(9600);

  second = 00;
  minute = 26;
  hour = 17;
  day = 3;
  date = 29;
  month = 1;
  year = 14;

  setDateDs1307(second, minute, hour, day, date, month, year);
}

void loop()
{
  byte second, minute, hour, day, date, month, year;

  getDateDs1307(&second, &minute, &hour, &day, &date, &month, &year);
  Serial.print(hour, DEC);
  Serial.print(":");
  Serial.print(minute, DEC);
  Serial.print(":");
  Serial.println(second, DEC);
  
  Serial.print(day, DEC);
  Serial.print("/");
  Serial.print(date, DEC);
  Serial.print(".");
  Serial.print(month, DEC);
  Serial.print(".");
  Serial.println(year, DEC);
  


  delay(1000);
}

Автору исхода спасибо.

#include "Wire.h"
#define DS1307_I2C_ADDRESS 0x68

byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}

byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}

void setDateDs1307(byte second,        // 0-59
                   byte minute,        // 0-59
                   byte hour,          // 1-23
                   byte dayOfWeek,     // 1-7
                   byte dayOfMonth,    // 1-28/29/30/31
                   byte month,         // 1-12
                   byte year)          // 0-99
{
   Wire.beginTransmission(DS1307_I2C_ADDRESS);
   Wire.write(0);
   Wire.write(decToBcd(second));    
   Wire.write(decToBcd(minute));
   Wire.write(decToBcd(hour));     
   Wire.write(decToBcd(dayOfWeek));
   Wire.write(decToBcd(dayOfMonth));
   Wire.write(decToBcd(month));
   Wire.write(decToBcd(year));
   Wire.endTransmission();
}

void getDateDs1307(byte *second,
          byte *minute,
          byte *hour,
          byte *dayOfWeek,
          byte *dayOfMonth,
          byte *month,
          byte *year)
{

  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.write(0);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 7);

  *second     = bcdToDec(Wire.read() & 0x7f);
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read() & 0x3f); 
  *dayOfWeek  = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month      = bcdToDec(Wire.read());
  *year       = bcdToDec(Wire.read());
}

void setup()
{
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
  Wire.begin();
  Serial.begin(9600);

  second = 45;
  minute = 3;
  hour = 7;
  dayOfWeek = 5;
  dayOfMonth = 17;
  month = 4;
  year = 8;
  setDateDs1307(second, minute, hour, dayOfWeek, dayOfMonth, month, year);
}

void loop()
{
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;

  getDateDs1307(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month, &year);
  Serial.print(hour, DEC);
  Serial.print(":");
  Serial.print(minute, DEC);
  Serial.print(":");
  Serial.print(second, DEC);
  Serial.print("  ");
  Serial.print(month, DEC);
  Serial.print("/");
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  Serial.print(year, DEC);
  Serial.print("  Day_of_week:");
  Serial.println(dayOfWeek, DEC);

  delay(1000);
}

Братка, Спасибо за код :) Ты как с неба подан :) Часы DS1307 с Китая работают на ура, так же и DS1302 http://ru.aliexpress.com/item/1pc-hot-sale-DS3231-AT24C32-IIC-Precision-RTC-Real-Time-Clock-Memory-Module-Free-Shipping/1997483734.html?recommendVersion=1