Arduino.ru

Если не секрет, что вы с нее хотите считать?

у нее ж нет аналоговых пинов

там есть пины А0, А1, А2 - что это? зачем?

Смена адреса I2C при необходимости.

о! Мне это будет необходимо! можно поподробнее?

Только если навешаете кучу девайсов и адреса начнут пересекатся. В противном случае забудте про них.

ну я планирую как минимум 2 дисплея

Если плата будет точно с таким же чипом, потребуется замкнуть перемычку на одной из плат.

а как мне узнать адресс платы? который я так понимаю надо вписать сюда 

lib_BlockLCD0802_IC lcd(0x27,16,2);

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknow error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

спасибо. А я то думал написано а0 а1 а2... думал что это компенсировали занятые аналоговые порты ардуины))

как говорится одним ударом - 2 зайцев. и про пины узнал, и про чтение имени.

Узнал что у этой платки имена колеблятся от 0х20 до 0х27... методом научного тыка, ну а как иначе если китайцы не прикладывают даташиты к своей продукции.

А китайцы тут не при чем. Есть даташит на PCF8574, в нем адресные поля и обозначены. 0х20-0х27 только для этой. С другими буквенными индексами могут быть другими.