Arduino.ru

#define NUMBER_OF_SHIFT_CHIPS   1 // количество регистров
#define DATA_WIDTH   NUMBER_OF_SHIFT_CHIPS * 8 // количество входов
#define PULSE_WIDTH_USEC   5 // задержка при считывании данных 

// для хранения считаных байт
// если регистров больше двух, то int меняется на long
#define BYTES_VAL_T unsigned int 

// пины для подключения регистра
int ploadPin = 8;//shift load selector 
int clockEnablePin = 9;
int dataPin = 11;//data GREEN 
int clockPin = 12;//clock 

BYTES_VAL_T pinValues; // текущее значение пинов 
BYTES_VAL_T oldPinValues; // предыдущее значение пинов

// функция для считывания пинов
BYTES_VAL_T read_shift_regs() {
    long bitVal;
    BYTES_VAL_T bytesVal = 0;

    // опрашиваем регистр о состоянии пинов
    digitalWrite(clockEnablePin, HIGH);
    digitalWrite(ploadPin, LOW);
    delayMicroseconds(PULSE_WIDTH_USEC);
    digitalWrite(ploadPin, HIGH);
    digitalWrite(clockEnablePin, LOW);

    // считываем полученные данные о пинах
    for(int i = 0; i < DATA_WIDTH; i++){
        bitVal = digitalRead(dataPin);
        bytesVal |= (bitVal << ((DATA_WIDTH-1) - i));
        digitalWrite(clockPin, HIGH);
        delayMicroseconds(PULSE_WIDTH_USEC);
        digitalWrite(clockPin, LOW);
    }
     
    // возвращяем результат опроса регистра
    return(bytesVal);
}

// функция для вывода состояния пинов
void display_pin_values(){
    // перебор всех пинов 
    for(int i = 0; i < DATA_WIDTH; i++){
        Serial.print("  Button-");
        Serial.print(i);
        Serial.print(": ");
        if((pinValues >> i) & 1){
          Serial.print("ON");
        }else{
          Serial.print("OFF"); 
        }   
        Serial.println();
    }
    Serial.println();
}

void setup(){
    // для вывода данных в монитор порта
    Serial.begin(115200);

    // установка режима работа пинов
    pinMode(ploadPin, OUTPUT);
    pinMode(clockEnablePin, OUTPUT);
    pinMode(clockPin, OUTPUT);
    pinMode(dataPin, INPUT);
    digitalWrite(clockPin, LOW);
    digitalWrite(ploadPin, HIGH);
// ***************************************************************** 
    // считываем значения с пинов
    pinValues = read_shift_regs();
    // выводим результат
    display_pin_values();
    // сохраняем текущее значение
    oldPinValues = pinValues;
}

void loop(){
    // считываем значения с пинов
    pinValues = read_shift_regs();
    // если значения изменились, то выводим их
    if(pinValues != oldPinValues){

      // выводим результат в монитор порта
        display_pin_values();
        // сохраняем текущее значение
        oldPinValues = pinValues;
    }
    delay(5);
}

результат выйдет так 

   Button-0: OFF

 Button-1: OFF