Arduino.ru

И снова здравствуйте.Навоял рабочий скетч,идеи пока реализованы не все.Так сказать промежуточный вариант скетча.Надо ещё работать и работать :)

 

Что он делает:Ставим на охрану:закрываем дверь,нажимаем кнопку вкл.Наоборот тоже можно.Сига на охране.

 

Снимаем с охраны просто нажатием на кнопку.Сработка:дверь открылась,сразу сирена 30 сек.Если после 30 сек шлейф целый снова охраняем,если шлейф разомкнут снимаем с охраны.

 

2 индикатора.зелёный контроль шлейфа,работает постоянно.Шлейф выкл мигает\вкл горит.

 

Красный индикатор вкл если сига вкл.

//Сигнализация для частного дома.Разработка:Zipper31.Mail:zz66zz@ya.ru

//постоянные
const byte GreenLed = 10; //зеленая лампочка
const byte RedLed = 11;  //красная лампочка
const byte Sirena = 9;  //сирена
const byte GerkonPin = 8; //геркон
const byte ButtonPin = 12; //пин для кнопки

//переменные
boolean PushOn = true;  // включать ли кнопку
boolean PushState = false;  // переменная кнопки
boolean SecureState = 0; //флаг работающей сигнализации
boolean GerkonState = 0; //флаг геркона
boolean LedState = 0; //флаг зелёного диода
boolean SecCont = 0; //для фиксации сработки

//таймеры
unsigned long previousMillis = 0;// обнуляем таймер диода
unsigned long previousMillisRest = 0;//обнуляем таймер сработки сиги
unsigned long intervalLed = 1000; //время мигания зелёного диода
unsigned long intervalRest = 30000; //время сирены и перепостановки на охрану

void setup()
{
  pinMode(GreenLed, OUTPUT); //задаем режимы работы пинов
  pinMode(RedLed, OUTPUT);
  pinMode(Sirena, OUTPUT);
  pinMode(GerkonPin, INPUT);
  pinMode(ButtonPin, INPUT_PULLUP);
}
void loop()
{ //управление кнопкой и защита от дребезга,получаем переменную PushState
  //какая то фигня написана неведомая,но работает хорошо :)
  boolean isButtonUp = digitalRead(ButtonPin);
  if (PushOn && !isButtonUp) {
    delay(5);
    isButtonUp = digitalRead(ButtonPin);
    if (!isButtonUp) {
      PushState = !PushState;
    }
  }
  PushOn = isButtonUp;

  GerkonState = digitalRead(GerkonPin); // назначаем переменную геркону

  //**********Включение сигнализации**********
  if (PushState == true) {    //сига включена и выполняем
    if (GerkonState == 1) {   //если "1" то
      SecureState = 1;
    }
  }      //следим за герконом и всё такое

  //**********Выключение сигнализации**********
  if (PushState == false) {    //сига выключена и выполняем
    digitalWrite(RedLed, LOW); //красный диод выкл
    digitalWrite(Sirena, LOW); //сирена выкл
    SecureState = 0;           //обнуляем
    SecCont = 0;
  }              //обнуляем

  //**********Охрана**********
  if (SecureState == 1) { //если "1" то
    if (GerkonState == 0 && SecCont == 0) { // если GerkonState"0"то погнали цикл
      SecCont = 1; // прерывание чтоб таймер сработки сиги не зациклился
      digitalWrite(Sirena, HIGH); //вкл сирена
      previousMillisRest = millis();
    }
  } //таймер сработки сиги
  if ((previousMillisRest > 0) && (millis() - previousMillisRest >= intervalRest)) {
    digitalWrite(Sirena, LOW); //выкл сирена
    if (GerkonState == 0)     //если геркон разомкнут"0" то
      PushState = false;     //вырубаем сигу
    else                      // если геркон замкнут"1"то
      SecCont = 0;         // обнуляем и опять охраняем
    previousMillisRest = 0;
  } //обнуляем таймер сработки сиги

  //**********Управление индикаторами**********
  //зелёный индикатор показывает режим шлейфа,всегда
  //красный индикатор показывает работу сигнализации
  digitalWrite(RedLed, PushState == true && GerkonState == 1); //вкл красный диод

  if (GerkonState == 0) //если "0" то
    digitalWrite(GreenLed, LedState); //мигаем зелёным диодом
  else                 //если "1" то
    digitalWrite(GreenLed, HIGH);     //светим постоянно

  //***Таймер индикатора,зелёный диод***
  unsigned long currentMillis = millis(); // частота мигания
  if (currentMillis - previousMillis > intervalLed) {
    previousMillis = currentMillis;
    if (LedState == LOW)
      LedState = HIGH;
    else
      LedState = LOW;
  }

}

Ещё прикручу пару таймеров и реализую набор кнопок на ТЛФ для отправки смс.Ещё есть мысль,звоним на ТЛФ сиги,она снимает трубку.Слушаем что происходит дома.Не забываем что это мой первый скетч. Что думаете про скетч и что ещё сделать?