Arduino.ru

Решил поделиться наработками.... и получить ХОРОШИЕ советы...

Поступил тут мне небольшой заказ (для товарища, т.е., бесплатно) на контроллер температуры в шкафу на балконе (там человек хранит всякие закатки/варенья/соленья и т.п.) До недавнего времени он использовал в качестве контроллера терморегулятор от холодильника. конструкция выглядела примерно так:

Щкаф разделен на два несвязанных отсека. В каждом отсеке установлен "нагреватель+вентилятор". Причем разведенная проводка подразумевает одновременное включение нагревателей. Нагреватель - это обычные лампочки на 220 вольт, а  вентиляторы - от БП на 12 вольт.

Сразу мне показалось как-то простовато все. Ставим два термодатчика (терморезисторы), переменный резистор для установки температуры, реле с обвязкой и полевик для управления вентиляторами.

Достаточно быстро все было размещено в корпус

Провод с терморезисторами выносной, клеммники для подключения нагревателя, входного напряжения и вентиляторов. Три светодиода - индикаторы состояния и сетевой блок питания 220-> 12 Вольт.

Все проверено, реле включается, вентилятор включается, есть некие показания от терморезисторов.

Мой первоначальный план написания скетча выглядел достаточно просто...

Типа такого алгоритма:

1) проверяем датчики температуры Один раз в секунду. И выбираем минимальное значение (в разных отсеках шкафа может быть разная)

Если с датчиком что-то не так (не подключен, в обрыве и ли еще что-то) ставим код ошибки (1 - первый датчик не работает, 2 - второй не работает, 3- оба датчика не работают)

2) если минимальное значение температуры меньше некого установленного пользователем (с помощью переменника) и код ошибки не равен 3,  включаем подогрев и запоминаем запоминаем температуру с которого начинается нагрев.

Чтобы реле не колбасилось (на граничном значении) греем пока минимальная температура с датчиков не станет выше установленной на несколько (допустим 7-10) градусов.

3) Если нагрев произошел  - выключаем подогреватели, но оставляем на некоторое время работать вентиляторы...

4) если нагрев не произошел за некое установленное время - ставим код ошибки 4 (проблема с нагревателем).

Попутно, между делом сигналим светодиодом о наличии ошибки (вспышками, количество которых равно коду ошибки)

Получился такой вот код:

/*
Терморегулятор на базе Ардуино нано
концепция вер 3. Кратко. 31-10-2015
Даже описывать нечего.
Есть процедура получения температуры с датчиков. Минимальная из них, но не =0
Если минимальное значение ниже некого установленного пользователем предела, включаем нагрев и греем пока не будет достигнута некая установленная
планка относительно установленной температуры
после этого еще немного работает вентилятор, "для утряски"
===================================
термодатчики по 10 кОм
Таблица значений:
  T    ->   ADC      Middle
=======|==========|==========
4  С  ->               274
7  С  -> 332..345      338
12 С  -> 355..367      361
14 С  -> 372..386      379
21 С  -> 443..457      450
22 С  -> 458..477      467
24 С  -> 513..526      519
*/

//отладочный вывод в ком-порт
#define debug 1
//======== Определение пинов =========
#define relePin 12
#define ledRele 10
#define fanPin 11
#define ledFan 14
#define ledPower 3
#define t1Pin A1
#define t2Pin A2
#define adjPin A3

//интервал времени, если в течении которого не произошел нагрев датчика, то выдаем код ошибки 4
#define timeWorkTen 10000
long int startWorkTen = 0; //переменная содержит значение времени включения ТЭНа

//Предопределяем интервал времени включения вентилятора
#define timeWorkFan 5000
long int startWorkFan=0; //переменная содержит значение времени включения FAN


long int timeReadTemperature = 0; //переменная содержит значение времени для считывания температуры
//Предопределяем интервал времени считывания значения температуры 1 раз в секунду
#define interval_read_temp 1000

// константы температурных диапазонов для регулировки
#define min_set_temp 270
#define max_set_temp 350
// довесок ПЛЮС к температуре установленной пользователем до которого греем
#define set_delta_temp 10


boolean releStatus = 0; //текущий статус реле
boolean fanStatus = 0; //текущий статус вентилятора

unsigned int heatStartTemp; //значение температуры  ДО включения нагревателя
unsigned int d_min_temp; // глобальная переменная "min температуры"
unsigned int userSetTemp; // установленное пользователем (Алексом) значение температуры, которого следует держаться

volatile byte errorCode = 0; //Код ошибки (1 - Первый датчик-Х, 2- 2-ой датчик -Х, 3 - оба датчика - Х, 4- нагреватель - Х)
volatile long int changeTime = 0; //глобальная переменная следующего вызова процедуры отображения ошибки светодиодом
#define pauseFlash 400 // пауза для красивого вывода кода ошибки

// выполняется только при старте программы
void setup() {
#if debug
  Serial.begin(9600);
#endif

  // инициализация пинов
  pinMode(relePin, OUTPUT);
  pinMode(ledRele, OUTPUT);
  pinMode(fanPin, OUTPUT);
  pinMode(ledFan, OUTPUT);
  pinMode(ledPower, OUTPUT);
  releOff();
  fanOff();

  changeTime = millis();
  d_min_temp = get_min_temp(); // сразу делаем замер значений температуры, что бы понимать ГДЕ МЫ


}

//=============================
// Основной цикл программы
void loop()
{

  if ((millis() - timeReadTemperature) >= interval_read_temp) // делаем замер температуры через некие интервалы времени
  {
    d_min_temp = get_min_temp();

#if debug
    Serial.print("Min_temperature: ");
    Serial.println(d_min_temp);
    Serial.print(" Set temp= ");
    Serial.println(userSetTemp);
    Serial.print(" errorCode= ");
    Serial.println(errorCode);
    Serial.print("heatStartTemp ");
    Serial.println(heatStartTemp);
    Serial.println("=============");
#endif
  }
  //=============
  // если есть ошибки, то нужно сигнализировать об этом
  //errorCode=0;
  if (millis() >= changeTime) showError(errorCode); //если есть ошибки и наступило время для след. этапа отображения ошибки
  //==============
  // считываем значение с переменника и пересчитываем его в заданный диапазон
  userSetTemp = map(analogRead(adjPin), 0, 1023, min_set_temp, max_set_temp);
 // userSetTemp = 560;
  //============
  // если миним. температура с датчиков ниже заданной и подогрев не включен и есть РЕАЛЬНЫЕ показания с датчиков, включаем подогрев
  if ((d_min_temp < userSetTemp) && (!releStatus) && (errorCode != 3))
  {
    heatStartTemp = d_min_temp; //запоминаем температуру с которой стартовали
    if (errorCode = 4) errorCode = 0;
    fanOn();
    releOn();
    startWorkTen = millis(); // запоминаем время старта

#if debug
    Serial.print("-------- Start HEAT. Time ");
    Serial.println(startWorkTen);
#endif
  }
  //==================
  //выключаем если нагрели
  if ((releStatus) && (d_min_temp > (userSetTemp + set_delta_temp)))
  {
    releOff();
    //fanOff();
    startWorkFan=millis();
#if debug
    Serial.println("-------- Stop HEAT.");
#endif
  }
  //==================
  //анализ ошибки нагревателя
  // если ТЭН включен, а температура осталась такой же (или еще хуже уменьшилась) в течении заданного промежутка времени
  // значит ТЭН не работает
  if ((releStatus) && (d_min_temp <= heatStartTemp) && (millis() - startWorkTen > timeWorkTen))
  {
    errorCode = 4;
  }

  //============
//Если был включен ТОЛЬКО вентилятор (без реле) и он отработал нужный интервал времени - выключаем его
 if ((fanStatus) and (!releStatus) and ((millis()-startWorkFan)>=timeWorkFan)) 
 {
   fanOff();
   
    #if debug
       Serial.println("----------- Stop Fan.");
     #endif
 }

} //end main loop
//===============================
void releOn() //включение реле
{
  digitalWrite (relePin, HIGH);
  digitalWrite (ledRele, HIGH);
  releStatus = true;
}

void releOff()//выключение реле
{
  digitalWrite (relePin, LOW);
  digitalWrite (ledRele, LOW);
  releStatus = false;
}

void fanOn() //включение вентилятора
{
  digitalWrite (fanPin, HIGH);
  digitalWrite (ledFan, HIGH);
  fanStatus = true;
}

void fanOff()//выключение вентилятора
{
  digitalWrite (fanPin, LOW);
  digitalWrite (ledFan, LOW);
  fanStatus = false;
}
//===================
// Процедура получения значения температуры с датчиков
// возвращаем только минимальное значение датчика
// и тут же происходит определение ошибок (коды:1..3)
int get_min_temp()
{
  unsigned int t1, t2;
  t1 = readTemp(t1Pin); //читаем значение с первого датчика
  t2 = readTemp(t2Pin);
  timeReadTemperature = millis(); //
  if (errorCode < 4) errorCode = 0; //если не проблема с нагревателем, то пока ставим код ошибки 0, а далее посмотрим
  /*
  #if debug
       Serial.print("D1:");
       Serial.println(t1);
       Serial.print("D2:");
       Serial.println(t2);
     #endif
   */
  if ((t1 == 0) and (t2 != 0)) //если РАБОТАЕТ только второй датчик
  {
    errorCode = 1;
    return t2;
  }
  if ((t1 != 0) and (t2 == 0)) //если РАБОТАЕТ только первый датчик
  {
    errorCode = 2;
    return t1;
  }

  if ((t1 == 0) and (t2 == 0)) //если НЕ РАБОТАЮТ ОБА датчика
  {
    errorCode = 3;
    return 0;
  }

  return (min(t1, t2)); //если предыдущие проверки не прошли - возвращаем минимальное значение температуры
}

//===================
// Функция считывания "усредненного" значения с нужного входа АЦП
unsigned int readTemp(byte pin)
{
  unsigned int tmpRead = 0;
  for (byte i = 0; i < 8; i++)
  {
    tmpRead += analogRead(pin);
  }
  tmpRead = tmpRead / 8;
  return tmpRead;
}


//====== Show error code =========
void showError(byte errorCode)
{
  static byte showErrorCount; //Глобальная переменная, видимая только этой процедурой
  if (errorCode == 0) 
    {
    digitalWrite(ledPower, HIGH); //Если нет ошибок, просто включаем светодиод
    changeTime = (millis() + pauseFlash);
    }
  else
  {
    if (showErrorCount == 0) //если попади сюда первый раз
    {
      showErrorCount = errorCode * 2; //ставим значение счетчика равное удвоенному коду ошибки
      digitalWrite (ledPower, LOW); //гасим светодиод
      changeTime = (millis() + 4 * pauseFlash); //следующий вызов через
    }
    else
    {
      if (showErrorCount % 2) //если внутренний счетчик кратен 2
      {
        digitalWrite (ledPower, HIGH); //включаем светодиод
        showErrorCount = showErrorCount - 1; //уменьшаем значение счетчика
        changeTime = (millis() + pauseFlash / 4); //для красоты, след. вызов через половину заданного интервала
      }
      else
      {
        digitalWrite(ledPower, LOW); //если попадаем на нечетное значение, гасим светодиод
        showErrorCount = showErrorCount - 1;
        changeTime = (millis() + pauseFlash);
      }
    }
  }
} //end show error

Однако не все так просто, как казалось на первый взгляд...

Кроме косяков с отображением кодов ошибок (в случае переполнения millis()) -  этот момент надеюсь всорости решить) что-то меня еще беспокоит.

Как то неправильно выглядит принудительный сброс ошибки №4 при старте нагрева :(

Если внимательно отнестись к исходным данным, а именно нарисовать и рассмотреть все возможные комбинации, то получается много чего интересного: