Arduino.ru

 Вернее не совсем так, "OUTLevel становится равным OUTLevel_temp"  - это не правильно.

OUTLevel становится равным результату вычисления

Что то как то всё сложно. Предлагаю свою версию. Датчик производит замер раз 10 в 1 минуту а потом вычисляет среднее значение и выводит его на стрелку.

 Ну как вариант я это тоже рассматривал, но есть небольшой ньюанс, этот же контроллер будет еще кое что делать, и если делать паузы между измерениями с помощью Delay, то и все сотальные функции будут тормозить

Забываем про псевдо-многозадачность))))) можно использовать прерывания по таймеру (пожертвовав 2 шим) или реализовать программно.

Ну можно и без задержки сделать

http://arduino.cc/en/Tutorial/BlinkWithoutDelay

  Ну яш написал что не програмист :)
А на счет сложности описанного метода, мне казалось что не так уж это и сложно. Вроде как по такому методу работают например указатели уровня топлива в автомобильных панелях приборов. (собственно свой вариант такого указателя я и делаю )

Можно и ваш метод использовать. Только осталось разобраться что вы имеете под словом такт?

Ну я имел ввиду за одно измерение

Нееее!!!!
Одно измерение будет происходить через определённое время или каждое прохождение Loop()?
 

 Ну я даже не знаю :)

Наверное каждое прохождение Loop()

Я думаю что через чур. Вы получите тоже самое что имеете сейчас. Так что лучше каждый раз опрашивать по времени. И ИМХО лучше вычислять среднее значение. Вроде так меньше кода будет. Хотя надо смотреть. Ещё шим задействованы?

 Да задействован еще один шим  на 5 ножке для второго указателя.

И еще настроен таймер для увеличения частоты ШИМ, в setup добавлена строчка:

TCCR0B = TCCR0B & 0b11111000 | 2;

иначе логометры гудят

Попробуйте так

int sensePin = 0; 
int OUTPin = 6; 
int Delay = 200;
unsigned long millisDelay, vals = 0;

void setup()
{
  pinMode(OUTPin, OUTPUT);
}
void loop()
{
  if(millis() > millisDelay){
    int val = analogRead(sensePin); 
    val = constrain(val, 45, 540);
    vals = vals*9/10+val;
    int OUTLevel = map(vals/10, 45, 540, 0, 200); 
    analogWrite(OUTPin, OUTLevel); 
    millisDelay = millis() + Delay;
  }
}

Инерция будет пропорционально зависить от переменной Delay. Если хотите то вожно сделать однонапрвленную инерцию....

Блин. Почему я плохо знаю программирование(((((
 

#include <MsTimer2.h>
static boolean output = HIGH;
int sensePin = 0; 
int OUTPin = 6;  
int mass[10];
int i=0;
void setup()
{
  pinMode(OUTPin, OUTPUT);
  MsTimer2::set(100, flash_led); //задержка
  MsTimer2::start();
}
void loop()
{  
  if (i==10)
  {
    i=0; 
    int val=0;   
    for(int j=0; j<=9; j++)
      val=val+mass[i];
    analogWrite(OUTPin, val/10);
  }    
}
void flash_led() 
{
  int val=constrain(analogRead(sensePin), 45, 540);
  mass[i] = map(val, 45, 540, 0, 200);
  i++;
}

 ОК ребята спасибо, поробую, попозже отпишусь по результатам теста

 maksim а что подразумевается под однаправленной инерцией?

Попробовал пока на столе, в качестве датчика - переменный резистор, в качестве индикатора - светодиод и еще добавил в код вывод значения OUTLevel в COM порт и смотрю на него через терминал.

При включении сначала уровень минимальный и растет до нужного значения, то есть стрелка будет наоборот при включении подниматься на максимум и опускаться до нужного уровня

При таком значении Delay примерно 7 секунд уходит на измение от полного уровня до 0

Вроде как все работает, завтра буду пробовать 

Значит, что сейчас при изменении в любую сторону значение инерционно, а можно например, чтобы при уменьшении значения была инерция, а при увеличении нет. Но я думаю когда речь идет об изменении уровня жидкости, то нужна инерция и на увеличение и на уменьшение.

Кстати, можно сделать так, чтобы при включении не было наростания т.е. чтобы при включении инерция отсутствовала. Для этого в функцию setup надо добавить строку:

vals = analogRead(sensePin)*10;

 Да, я тоже так думаю, она же плещется во все стороны :)

ОК завтра когда со стрелкой буду тестировать, попробую без наростания и с наростанием 

Теперь нужно добавить еще один датчик с указателем и светодиод низкого уровня
Второй датчик сам по себе инерционный и там стрелка не скачет.
При увеличении частоты ШИМа и время инерции уменьшилось, поэтому сделал Delay = 1000.

Но возник глюк, почему то при изменени сопротивления одного датчика меняется уровень на обоих указателях

Где то видимо накосячил:

int sensePin = 0;
int OUTPin = 6;
int sensePin2 = 2;
int OUTPin2 = 5;
int dut = 8;
int Delay = 1000;
unsigned long millisDelay, vals = 0;


void setup()
{
  TCCR0B = TCCR0B & 0b11111000 | 2;
  pinMode(OUTPin, OUTPUT);
  pinMode(OUTPin2, OUTPUT);
}
void loop()
{
  if(millis() > millisDelay)
   {
    int val = analogRead(sensePin);
    val = constrain(val, 45, 540);
    vals = vals*9/10+val;
    int OUTLevel = map(vals/10, 45, 540, 30, 200);
    analogWrite(OUTPin, OUTLevel);
    if (OUTLevel >= 157) {digitalWrite(dut, HIGH);} else {digitalWrite(dut, LOW);}
    millisDelay = millis() + Delay;
    int val2 = analogRead(sensePin2);
    val2 = constrain(val2, 150, 988);
    int OUTLevel2 = map(val2, 150, 988, 30, 230);
    analogWrite(OUTPin2, OUTLevel2);
    }
}

Я так понял добавили светодиод dut = 8; но почему то он завязан на показания первого датчика

Если так задумано прошу прощения)

 Да, этот диод для первого датчика. 

Второй- датчик температуры, потом к нему тоже добавлю пару диодов - прогрев и перегрев 

 Может что не так подключили?

Да вот как раз сижу смотрю...

Собирал пока на макетке, к машине еще не подключал.  

В коде косяков нет? 

Вроде бы нет, попробуйте так

int sensePin = 0;
int OUTPin = 6;
int sensePin2 = 2;
int OUTPin2 = 5;
int dut = 8;
int DelayLevel = 1000;
int DelayTemp = 500;
unsigned long millisDelayLevel, millisDelayTemp, vals = 0;


void setup()
{
  TCCR0B = TCCR0B & 0b11111000 | 2;
  pinMode(OUTPin, OUTPUT);
  pinMode(OUTPin2, OUTPUT);
}
void loop()
{
  if(millis() > millisDelayLevel)
  {
    int val = analogRead(sensePin);
    val = constrain(val, 45, 540);
    vals = vals*9/10+val;
    int OUTLevel = map(vals/10, 45, 540, 30, 200);
    analogWrite(OUTPin, OUTLevel);
    if (OUTLevel >= 157) {
      digitalWrite(dut, HIGH);
    } 
    else {
      digitalWrite(dut, LOW);
    }
    millisDelayLevel = millis() + DelayLevel;
  }
  
  if(millis() > millisDelayTemp)
  {
    int val2 = analogRead(sensePin2);
    val2 = constrain(val2, 150, 988);
    int OUTLevel2 = map(val2, 150, 988, 30, 230);
    analogWrite(OUTPin2, OUTLevel2);
    millisDelayTemp = millis() + DelayTemp;
  }
}

тут опрос датчиков производится не зависимо друг от друга.

 Хм, видимо каие-то наводки в самой макетке.

Датчик (переменный резистор) у меня один, подключаю его по почереди то к одному входу то к другому и один из входов остается в воздухе. Если его коснуться пальцем - наводка пропадает.  Надо было подтянуть к земле

maksim еще раз спасибо большое за помощь!!!

Попробую на машине - отпишусь.

 Вобщем все отлично!  

Скетч залил, инерцию при старте убрал, delay еще увеличил до 2000. Машину шатал - стрелка стоит как вкопаная. Поеду с работы домой вечером - проверю на ходу. 

Естественно, когда вывод в воздухе значение будет хаотично меняться.

Так может вместо стрелочных приборов задуматься о цифровых индикаторах? 

 Да не, меня устраивают стрелки :)

Просто поставил приборную панель от другой машины, а там датчик уровня топлива имел другое сопротивление и указатель врал, а указатель температуры вообще информацию получал с мозга в цифровом виде. Пришлось сделать управление этими указателями с отдельного контроллера :)

Так в том то и дело что не хаотично, это и сбило меня столку. Кручу резистор и обе стрелки синхронно поднимаются-опускаются.

 Следующий этап - сделать индикатор номера передачи АКПП.

Займусь если получится на следующей неделе, наброски уже есть :)