Arduino.ru

Кстати! Та же история и с DS18B20. С библиотеками OneWire.h и DallasTemperature.h не работает от внутренего генератора 8МГц.

у вас ардуина на какую частоту настроена?

дело в том, что всякие функции програмной задержки типа delay работают гоняя пустные циклы, количество циклов на одну мсек зависит от частоты МК и определяется при компиляции. Если компилятор настроен неверно, то и константы выйдут не верно и значит и протоколы тип 1-wire (а DHT использует похожий протокол) не смогут работать

в детали не погружался, но если используете бутлоадер откомпилированный на 1мгц и в boards.txt у вас прописан 1МГц то все должно работать

У меня OneWire c DS18B20 на Atmega8 c внутренним генератором 8МГц работает вот прямо сейчас на столе. "Что я делаю не так" (с) :)

Поделитесь кодом

Вот мой

#include <LiquidCrystal.h>
LiquidCrystal lcd(14,15,16,17,18,19);
#include <OneWire.h>
#include <DallasTemperature.h>
#define ONE_WIRE_BUS 0
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);

void setup(void) {
    sensors.begin();
    lcd.begin(16, 2);
}

void loop(void) 
{
  sensors.requestTemperatures(); 
  lcd.setCursor(0,0); 
  lcd.print(sensors.getTempCByIndex(0));
}

Пример OneWire "DS18x20_Temperature" прекрасно работает.

#include <OneWire.h>

// OneWire DS18S20, DS18B20, DS1822 Temperature Example
//
// http://www.pjrc.com/teensy/td_libs_OneWire.html
//
// The DallasTemperature library can do all this work for you!
// http://milesburton.com/Dallas_Temperature_Control_Library

OneWire  ds(10);  // on pin 10 (a 4.7K resistor is necessary)

void setup(void) {
  Serial.begin(9600);
}

void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
  
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
  
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}

Да! Работает!
И вот этот код тоже

#include <OneWire.h>
OneWire ds(15);
#include <LiquidCrystal.h>
LiquidCrystal lcd(5,4,3,2,1,0);
int Read = 0;
byte tdata[2];

void setup() {
 lcd.begin(16, 2);
}

void loop() {

ds.reset(); 
ds.write(0xCC);
ds.write(0x44);
delay(750);
ds.reset();
ds.write(0xCC);
ds.write(0xBE);
tdata[0] = ds.read(); 
tdata[1] = ds.read();
Read = (tdata[1]<< 8)+tdata[0];
Read = Read>>4;
lcd.setCursor(0,0);
lcd.print(Read);
}

Но на 4, 2 и 1 МГц не хочет. А вот DHT11(22) и на 8 МГц отказывается!

Удалось ли решить проблему пониженной частоты?
У меня ds18b20 работает только на 8 МГц, ниже не хочет.
Boards.txt правлю, диоды мигают с нужными интервалами, передатчик на virtualware работает. Может в библиотеке Onewire что поправить можно?

sasha_ml, ну очевидно что дуина не может при тактовой 1МГц соблюдать нужные тайминги. Можно попробовать все вызовы delayMicroseconds() в библиотеке поменять   на _delay_us(),  либо найти не дуиновскую библиотеку.