Arduino.ru

Здравствуйте, пишу от отчаяния. Потратил неделю на прошивку этой платы.

Делаю проект Telegram + датчики воды / температуры / дыма. Есть у меня Wemos D1 c esp8266 на борту, все прошил, все отлично, но уперся в один аналоговый выход, этого для меня очень мало.

Решил купить навороченнее плату чтобы много выходов, вайфай на борту. Приобрел на свою голову две платы:

https://www.aliexpress.com/item/GREATZT-UNO-WiFi-R3-ATmega328P-ESP8266-32Mb-memory-USB-TTL-CH340G-For-Arduino-Uno-NodeMCU-WeMos/32963516971.html?spm=a2g0s.9042311.0.0.4e5a4c4d0CIuE4

Выставил пины 5/6/7 в ON, остальные OFF, прошил, отключил 7 пин, в мониторе порта вайфай подключился, а вот датчики не показывает. Пробовал прошить Blink - тоже ноль на массу. Прошило 100%, а мигает как обычно.

Пробовал менять версии библиотек, менять платы в настройках плат, менять настройки прошивки, облазил весь интернет. Короче за неделю я забрутфорсил почти все варианты прошивки. Плата отправляет сообщения в телеграм, видит входящие, но вот датчики не видит. Я уже все порты перепробовал.

Так как купил две таких, подумал первая брак, у второй аналогичное поведение. Датчики живые, вставляю в старую Wemos D1 - все прекрасно.

Сейчас настройки на которых прошивается успешно и работает телеграм:

Помогите пожалуйста разобраться, я уже сделал все что смог.

Код программы:

#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>
#include <FS.h>
#include <ArduinoJson.h>
#include "DHT.h"

#define alarm 0 //Активная пищалка подключается на D4 плюсом и минусом на GND
#define DHTPIN 2 // Датчик температуры
#define DHTTYPE DHT22
#define BOTtoken "714045601:AAE92GHOC-z3lAqVm_nRA5as5sh1ju8tcgs"

DHT dht(DHTPIN, DHTTYPE);

char ssid[] = "Natella";     // your network SSID (name)
char password[] = "Natella1103"; // your network key

WiFiClientSecure secured_client;
UniversalTelegramBot bot(BOTtoken, secured_client);

int Bot_mtbs = 2000; // mean time between scan messages
long Bot_lasttime;   // last time messages' scan has been done

int bulk_messages_mtbs = 1500; // mean time between send messages, 1.5 seconds
int messages_limit_per_second = 25; // Telegram API have limit for bulk messages ~30 messages per second

String subscribed_users_filename = "subscribed_users.json";

DynamicJsonBuffer jsonBuffer;

void handleNewMessages(int numNewMessages) {
  Serial.println("handleNewMessages");
  Serial.println(String(numNewMessages));

  for (int i = 0; i < numNewMessages; i++) {
    String chat_id = String(bot.messages[i].chat_id);
    String text = bot.messages[i].text;

    String from_name = bot.messages[i].from_name;
    if (from_name == "") from_name = "Guest";

    if (text == "/start") {
      if (addSubscribedUser(chat_id, from_name)) {
        String welcome = "This is Bulk Messages example.\n\n";
        welcome += "/showallusers : show all subscribed users\n";
        welcome += "/testbulkmessage : send test message to subscribed users\n";
        welcome += "/removeallusers : remove all subscribed users\n";
        welcome += "/stop : unsubscribe from bot\n";
        bot.sendMessage(chat_id, welcome, "Markdown");
      } else {
        bot.sendMessage(chat_id, "Something wrong, please try again (later?)", "");
      }
    }

    if (text == "/stop") {
      if (removeSubscribedUser(chat_id)) {
        bot.sendMessage(chat_id, "Thank you, " + from_name + ", we always waiting you back", "");
      } else {
        bot.sendMessage(chat_id, "Something wrong, please try again (later?)", "");
      }
    }

    if (text == "/testbulkmessage") {
      sendMessageToAllSubscribedUsers("ATTENTION, this is bulk message for all subscribed users!");
    }

    if (text == "/showallusers") {
      File subscribedUsersFile = SPIFFS.open("/" + subscribed_users_filename, "r");

      if (!subscribedUsersFile) {
        bot.sendMessage(chat_id, "No subscription file", "");
      }

      size_t size = subscribedUsersFile.size();

      if (size > 1024) {
        bot.sendMessage(chat_id, "Subscribed users file is too large", "");
      } else {
        String file_content = subscribedUsersFile.readString();
        bot.sendMessage(chat_id, file_content, "");
      }
    }

    if (text == "/removeallusers") {
      if (SPIFFS.remove("/" + subscribed_users_filename)) {
        bot.sendMessage(chat_id, "All users removed", "");
      } else {
        bot.sendMessage(chat_id, "Something wrong, please try again (later?)", "");
      }
    }
  }
}

JsonObject& getSubscribedUsers() {
  File subscribedUsersFile = SPIFFS.open("/" + subscribed_users_filename, "r");

  if (!subscribedUsersFile) {
    Serial.println("Failed to open subscribed users file");

    // Create empty file (w+ not working as expect)
    File f = SPIFFS.open("/" + subscribed_users_filename, "w");
    f.close();

    JsonObject& users = jsonBuffer.createObject();

    return users;
  } else {

    size_t size = subscribedUsersFile.size();

    if (size > 1024) {
      Serial.println("Subscribed users file is too large");
      //return users;
    }

    String file_content = subscribedUsersFile.readString();

    JsonObject& users = jsonBuffer.parseObject(file_content);

    if (!users.success()) {
      Serial.println("Failed to parse subscribed users file");
      return users;
    }

    subscribedUsersFile.close();

    return users;
  }
}

bool addSubscribedUser(String chat_id, String from_name) {
  JsonObject& users = getSubscribedUsers();

  File subscribedUsersFile = SPIFFS.open("/" + subscribed_users_filename, "w+");

  if (!subscribedUsersFile) {
    Serial.println("Failed to open subscribed users file for writing");
    //return false;
  }

  users.set(chat_id, from_name);
  users.printTo(subscribedUsersFile);

  subscribedUsersFile.close();

  return true;
}

bool removeSubscribedUser(String chat_id) {
  JsonObject& users = getSubscribedUsers();

  File subscribedUsersFile = SPIFFS.open("/" + subscribed_users_filename, "w");

  if (!subscribedUsersFile) {
    Serial.println("Failed to open subscribed users file for writing");
    return false;
  }

  users.remove(chat_id);
  users.printTo(subscribedUsersFile);

  subscribedUsersFile.close();

  return true;
}

void sendMessageToAllSubscribedUsers(String message) {
  int users_processed = 0;

  JsonObject& users = getSubscribedUsers();

  for (JsonObject::iterator it = users.begin(); it != users.end(); ++it) {
    users_processed++;

    if (users_processed < messages_limit_per_second)  {
      const char* chat_id = it->key;
      bot.sendMessage(chat_id, message, "");
    } else {
      delay(bulk_messages_mtbs);
      users_processed = 0;
    }
  }
}

void alarmLow() {
  tone(alarm, 1000, 900);
  delay(3000);
  tone(alarm, 1000, 900);
  delay(3000);
  tone(alarm, 1000, 900);
  delay(3000);
}

void alarmHigh() {
  tone(alarm, 1000, 1200);
  delay(2000);
  tone(alarm, 1000, 1200);
  delay(2000);
  tone(alarm, 1000, 1200);
  delay(2000);
  tone(alarm, 1000, 1200);
}

void setup() {
  pinMode(A0, INPUT); //Укажем что порт A0 будет использован на вход
  //pinMode(SPIN, INPUT);
  Serial.begin(115200);
  delay(10);
  dht.begin();

  if (!SPIFFS.begin()) {
    Serial.println("Failed to mount file system");
    return;
  }

  // attempt to connect to Wifi network:
  Serial.print("Connecting Wifi: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  if (millis() > Bot_lasttime + Bot_mtbs)  {
    int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

    int h = dht.readHumidity();
    float t = dht.readTemperature();
    int s = analogRead(A0);
    //int s = digitalRead(SPIN);
    String smoke = String(((s / 10 - 8) * 3));
    String smoke_alarm = "ALARM! Smoke value too high: " + String(s) + " (" + smoke + "%)";

    if (s > 300) {
      sendMessageToAllSubscribedUsers(smoke_alarm);
      alarmLow();
    } else if (s > 420) {
      sendMessageToAllSubscribedUsers(smoke_alarm);
      alarmHigh();
    }

    String outputText = "Temperature: " + String(t) + "°C, " + "Humidity: " + h + "%, "
                        + "Smoke: " + String(s) + " (" + smoke + "%)";
    Serial.println(outputText);

    //    if (digitalRead(SPIN) == LOW) {
    //      sendMessageToAllSubscribedUsers(smoke_alarm);
    //      alarmHigh();
    //    }

    while (numNewMessages) {
      Serial.println("got response");
      handleNewMessages(numNewMessages);
      for (int i = 0; i < numNewMessages; i++) {
        bot.sendMessage(bot.messages[i].chat_id, outputText, "");
      }
      numNewMessages = bot.getUpdates(bot.last_message_received + 1);
      //sendMessageToAllSubscribedUsers(outputText);
    }

    Bot_lasttime = millis();
  }
}