Arduino.ru

#include <OneWire.h>

#define NumPin 70 //колличество пинов на используемой плате ардуино (для примера - MEGA)(Uno=20)
#define NumConfigPin 69 //(A15)//выделенный пин для программирования номеров датчиков(Uno=19-(A5))
int NumSens;//колличество обнаруженых датчиков
boolean PinNumSens[NumPin - 3];//массив задействованных(true) или нет(false) пинов для датчиков(не включая пин 0 и 1 UART и выделенный пин)
unsigned long timeSens;//время события
int diftime = 0;//разница времени между двумя событиями
boolean ReadSens = false;//признак чтения\записи датчика

void setup() {
  Serial.begin(9600);
  Serial.println(F("Start Search for Sensors:"));
  SearchNumSens();
}

void loop() {

  if (Serial.available()) {
    String SerialRead = Serial.readString();
    if (SerialRead == "s") {//поиск числа датчиков и задействованных пинов
      SearchNumSens();
    }
    else {//запись номера датчика в его EEPROM на выделенном пине NumConfigPin
      int Num = SerialRead.toInt();
      Serial.print(F("Sensors Number Recording: #"));
      Serial.print(Num);
      if (Num < 1) {
        Serial.println(F(" Number Error"));
      }
      else if (NumConfigSens(Num)) {
        Serial.println(F(" OK"));
      }
      else {
        Serial.println(F(" Error"));
      }
    }
  }
  //что-бы не мешало переполнение millis
  if (timeSens > millis()) {
    diftime = int(4294967295 - timeSens + millis());
  }
  else {
    diftime = int(millis() - timeSens);
  }

  if (ReadSens == false) {
    for (byte i = 2; i < NumConfigPin; i++) {
      if (PinNumSens[i - 2] == true) {
        OneWire  ds(i);
        // обращение ко всем датчикам шины сразу:
        ds.reset();//сброс шины
        ds.write(0xCC);//Игнорировать адрес
        ds.write(0x44);//начать преобразование температуры(без паразитного питания)
      }
    }
    ReadSens = true;
    timeSens = millis();
  }
  else if (ReadSens == true && diftime >= 1000) {//1000ms(с запасом)-т.к. время преобразования =750ms для
    // default value of Config = 0x7F (user byte 3)

    int Sensor[NumSens][3];//значения опроса датчиков
    int N = 0;//число корректно ответивших датчиков
    for (byte n = 2; n < NumConfigPin; n++) {
      if (PinNumSens[n - 2] == true) {
        OneWire  ds(n);
        byte addr[8];
        while (N <= NumSens) {
          if ( !ds.search(addr)) {
            break;
          }
          for (byte c = 0; c < 2; c++) {
            byte present = ds.reset();//признак готовности датчика к ответу
            ds.select(addr);
            ds.write(0xBE);//Чтение памяти
            byte data[9];
            for (byte d = 0; d < 9; d++) {
              data[d] = ds.read();
            }
            byte CRC = OneWire::crc8(data, 8);
            if (CRC == data[8] && present == 1 && CRC != 0) {//ответ корректный
              if (N < NumSens) {
                Sensor[N][0] = data[0];
                Sensor[N][1] = data[1];
                Sensor[N][2] = data[3] * 10 + data[2];//номер датчика
              }
              N++;
              break;
            }
            else if (c == 0) {//датчик отсутсвует или мусор
              Serial.println(F("CRC!"));
              delay(100);
            }
            else {
              Serial.println(F("Sensors CRC Error"));
            }
          }
        }
        if (N > NumSens) {
          break;
        }
      }
    }
    // >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    // просто пример обработки показаний датчиков,
    // если их нумерация непрерывная с первого номера,
    // хотя не обязательно - тогда каждый отдельно,
    // а номера должны быть любые неповторяющиеся
    for (int SensorN = 1; SensorN <= NumSens; SensorN++) {
      int16_t DataT = DataSens(SensorN, Sensor);
      if (DataT == -1000) {
        Serial.print(F("Error"));
      }
      else {
        double SensT = (double)DataT / 16.0;//для библиотеки PID например
        Serial.print(SensT);
        Serial.print(F("*C"));
      }
      Serial.print(F(" Sensor #"));
      Serial.println(SensorN);
    }
    Serial.println();
    // >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    if (N > NumSens) {
      Serial.println(F("Find New Sensor. Start Search:"));
      SearchNumSens();
    }
    ReadSens = false;
  }
}
//=========================================================
//поиск нужного значения температуры в массиве по номеру датчика
int16_t DataSens(int SensorN, int Sensor[][3]) {
  int16_t rawData = -1000;//любое нереальное значение
  for (byte i = 0; i < NumSens; i++) {
    if (Sensor[i][2] == SensorN) {
      rawData = (Sensor[i][1] << 8) | Sensor[i][0];
      break;
    }
  }
  return rawData;
}
//=========================================================
//запись номера датчика в его EEPROM
boolean NumConfigSens(int NumConfig) {
  byte v1 = NumConfig % 10;
  byte v2 = (NumConfig - v1) / 10;
  OneWire  ds(NumConfigPin);
  ds.reset();//сброс шины
  ds.write(0xCC);//Игнорировать адрес
  ds.write(0x4E);//разрешение записать конфиг //write scratchpad (starts at byte 2)
  ds.write(v1);//value of user byte 1
  ds.write(v2);//value of user byte 2
  ds.write(0x7F);//default value of Config = 0x7F (user byte 3)//точность преобразования
  ds.reset();//сброс шины - обязательно до задания следующей комманды копирования в EEPROM
  ds.write(0xCC);//Игнорировать адрес
  ds.write(0x48);// копируем три байта в EEPROM DS18B20, чтобы сохранить постоянно
  delay(20);//ждём, пока закончит запись
  ds.reset();//сброс шины - обязательно до задания следующей комманды копирования в ОЗУ
  ds.write(0xCC);//Игнорировать адрес
  ds.write(0xB8);//Данные перезагружены из EEPROM в ОЗУ
  ds.reset();//сброс шины - обязательно до задания следующей комманды чтения из ОЗУ
  ds.write(0xCC);//Игнорировать адрес
  ds.write(0xBE);//Чтение памяти - нам нужны только байт 2,3
  ds.read();//нам не нужен(0)
  ds.read();//нам не нужен(1)
  if (ds.read() == v1 && ds.read() == v2) {
    return true;
  }
  else {
    return false;
  }
}
//=========================================================
//поиск числа датчиков и задействованных пинов
void SearchNumSens() {
  NumSens = 0;
  byte addr[8];
  for (byte n = 2; n < NumConfigPin; n++) {
    PinNumSens[n - 2] = false;
    OneWire  ds(n);
    while (true) {
      if ( !ds.search(addr)) {
        break;
      }
      Serial.print(F("Pin #"));
      Serial.print(n);
      Serial.print(F(":\r\nROM = "));
      for (byte i = 0; i < 8; i++) {
        Serial.print(addr[i], HEX);
        Serial.print(' ');
      }
      if (OneWire::crc8(addr, 7) == addr[7]) {
        ds.reset();//сброс шины - обязательно до задания следующей комманды чтения из ОЗУ
        ds.select(addr);
        ds.write(0xBE);//Чтение памяти - нам нужны только байт 2,3
        ds.read();//нам не нужен(0)
        ds.read();//нам не нужен(1)
        Serial.print(F("Sensor #"));
        Serial.println(ds.read() + ds.read() * 10);
        NumSens++;
        PinNumSens[n - 2] = true;
      }
      else {
        Serial.println(F("Sensors ID Error!"));
      }
    }
  }
  Serial.print(F("\r\nNumber of Sensors = "));
  Serial.println(NumSens);
  Serial.println();
}