Arduino.ru

мне интересно, как пользоваться 000'000'000 ?

как, блин, этим можно хоть как-то пользоваться?

Ну, лично Вас я, как Вам известно, консультирую только на коммерческой основе. Сегодня, ради того, что Луна в знаке Овна за два дня до полнолуния, я сделаю исключение и отвечу на этот вопрос, но впредь (если захочется узнать как свёрткой пользоваться, например) - размещайте заказ на "Ищу исполнителя".

void setup(void) {
	Serial.begin(57600);
	long frequency = 16'000'000;
	Serial.print(frequency);
}

void loop(void) {}

И что, в порт правда выводит "16'000'000"?

Запустите :)

Нет, конечно, это чисто для читабельности текста программы, чтобы не считать нули в попытках понять там 16МГц или 1,6МГц (в том же экселе есть опция разделения разрядов для тех же целей).

Кстати, попробовал свёртку на тривиальном примере. Один в один с ручным написанием (без свёртки) и по времени, и по памяти. Буду придумывать менее тривиальный пример.

А этот - вот он (задача: выдать на пин 10 операцию OR по пинам 2-4, а на пин 11 - операцию OR по пинам 5-6)

//
// Пины контроля периметра
//
static const int8_t pinPerimeter1 = 2;
static const int8_t pinPerimeter2 = 3;
static const int8_t pinPerimeter3 = 4;
//
// Пины контроля освещённости замков
//
static const int8_t pinLock1 = 5;
static const int8_t pinLock2 = 6;

template <class... Args>
inline bool orPins(Args... args) { 
	return (digitalRead(args) || ...); 
}

inline void checkAlarms(void) {
	const bool perimeter = orPins(pinPerimeter1, pinPerimeter2, pinPerimeter3);
	const bool locks = orPins(pinLock1, pinLock2);
	digitalWrite(10, perimeter);
	digitalWrite(11, locks);
}

void setup(void){ 
	Serial.begin(57600); 
	pinMode(10, OUTPUT);
	pinMode(11, OUTPUT);
} 

void loop(void) {
	checkAlarms();
}

А зачем запускать то, результат чего известен заранее?

Лично я отношусь с категоричным сторонникам принципа "если работает, ничего не трогай!", поэтому у меня стоит v.1.6.5.

судя по тому, как часто российские космолёты падают в Туву - лично вашим студентам ваша работа и даром не нужна.

void setup(void) {
	Serial.begin(57600);
	long frequency = 16'000'000;
	Serial.print(frequency);
}

void loop(void) {}

это нихера не ответ на мой вопрос.

А эта штука наплодит функций под кажный вариант, как и в ранних gcc?

template <class... Args>
inline bool orPins(Args... args) {
    return (digitalRead(args) || ...);
}

Хотя, видимо, всё развернётся в такое?

const bool perimeter = digitalRead(pinPerimeter1) || digitalRead(pinPerimeter2) || digitalRead(pinPerimeter3);

Ну, разумеется. И дело тут не в ранних GCC, а в шаблонах - они по жизни плодят по одной функции под каждый уникальный набор параметров.

Значит, Вам не повезло :(

Цикл по массиву (range-based for statement). Симпатично. Работает

void setup(void){ 
	int allPins[] = { 2, 3, 4, 5, 6};
	for (int pin : allPins) pinMode(pin, HIGH);
	for (int pin : allPins) digitalWrite(pin, HIGH);
} 

void loop(void) {}

А как там насчёт захвата *this лямбдами и инициализации в if'ах и switch'ах? А inline переменные пашут?

За лямбды сами разбирайтесь или Пуха зовите.

inline переменные и локальные объявления в if и switch - легко:

void setup(void){ 
	pinMode(LED_BUILTIN, HIGH);
} 

inline uint32_t halfPerios = 500;

void loop(void) {
	static uint32_t lastMillis;
	if (uint32_t currentMillis = millis(); currentMillis - lastMillis > halfPerios) {
		lastMillis = currentMillis;
		digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
	}
}

template <class... Args>
inline bool orPins(Args... args) {
    return (digitalRead(args) || ...);
}

const bool perimeter = digitalRead(pinPerimeter1) || digitalRead(pinPerimeter2) || digitalRead(pinPerimeter3);

вот можешь жеж, это возвращаясь к скетчу для 328PB по поочередной проверке всех таймеров миганием диода на 13-м

Сорри, вчера как-то пропустил.

const bool perimeter = digitalRead(pinPerimeter1) || digitalRead(pinPerimeter2) || digitalRead(pinPerimeter3);

Не совсем так.

Свёртки бывают левосторонние и правосторонние, а также унарные и бинарные. У меня в примере унарная правосторонняя свёртка и она развернётся в

const bool perimeter = ((digitalRead(pinPerimeter1)) || ((digitalRead(pinPerimeter2)) || (digitalRead(pinPerimeter3))));

Обратите внимание на порядок выполнения операций - справа налево.

const bool perimeter = ((digitalRead(pinPerimeter1)) || ((digitalRead(pinPerimeter2)) || (digitalRead(pinPerimeter3))));

Порядок определяется тем, что вычисляется условие (как "ленивое сравнение" в if()) или же это свойство новомодной свёртки?

Порядок - свойство свёртки. Но ленивость никто не отменял - она сама по себе.

Если бы вместо

return (digitalRead(args) || ...);

было написано

return (... || digitalRead(args));

то это была бы левосторонняя свёртка и скобки стали бы наоборот, чтобы слева направо выполнялось.

Да Вы сами поэкспериментируйте. Надо только в platforms.txt заменить -std=gnu++11  на -std=gnu++1z, чтобы 2017-ый стандарт включить. (почему "z" - не знаю, вроде 7 тоже работала, но в документации сказано "z")

а авто авто можно писать?

мне больше всего нравилось это

auto var = blablafunc();

и это

for each (auto var in obj)

и очень не нравится что написанный код на Си как черный ящик в плане того что я не могу посмотреть какой там ассемблер сгенерировал компилятор для того или иного кода на Си

или есть где то такой файл с ассемблером в папке с проектом?

А, ну я понял,  - троеточие определяет направление подстановки аргументов из декларации функции.

Штука интересная, но надо подумать, конечно, где она выгодно ляжет в код...

Ради Бога. Это и раньше можно было. Прямо "из коробки" безо всяких изменений опций.

Если std поставите

Ну, кто ж Вам виноват, что Вы не можете. Кому надо - могут.

Поставите нужные опции - будет.

подскажите где какие опции поставить чтоб файлик с ассемблером улицезреть? плиз

Оно (отточие) ещё и посерёдке бывает в бинарных свёртках. Погуглите и попробуйте в реальном компиляторе.

Я так сходу не помню, это рыться надо - искать, а тут рабочий день начинается. Откройте отдельную тему, кто-нить подскажет или уж я после рабочего дня поищу и напишу.

вот такие вкусняшки я раньше использовал в C++/CLI, и вообще последнее время писал только на нем, очень кайфовый язык
с менеджером памяти и другими плюшками

int main(array<System::String ^> ^args)
{
	auto arr = File::ReadAllLines("C:/Projects/gen_flash/gen_zaylist.pls");

	for each (String^ l in arr)
	{
		if (l->Contains("http://"))
		{
			l = Regex::Match(l, "=(.+)$")->Groups[1]->Value;
			add_waiting(l);
		}
	}

	return 0;
}

Это "Ваш проблем". Arduuino IDE тут не при делах.

Вот, до чего ж народ ленивый! Всё самому надо делать!

Пух, нет повода не выпить, *this нормально передаётся через замыкание, а заодно и умолчания для параметров шаблонов нормально работают.

Пример - неблокирующий блинк на 4 Гц

static constexpr uint32_t halfPeriod = 125;

template <uint8_t pin = LED_BUILTIN> class ThePin {
	uint32_t m_old;
	void Set(const bool state) const { digitalWrite(pin, state); }
	bool isLow(void) const { return !(uint8_t)digitalRead(pin); }
public:	
	ThePin(void) { pinMode(pin, OUTPUT); }
	auto operator() (void) {
		 return [=] {  
		 	if (const uint32_t cur = millis(); cur - m_old > halfPeriod) {
		 		m_old = cur; 
		 		Set(isLow()); 
		 	}
		}; 
	}
};

void setup(void) {} 

void loop(void) {
	static ThePin pin;
	pin()();
}

Так ото ж!

О, в си подвезли foreach (#11), к 2020 году-то :)

вы чо тут кодом материтесь-то?  Мы с котом смотрим в это мракобесие и плачем. :( 

Фигвам! Это не настоящий foreach. Хотя, он во многих языках не настоящий.

Дед, ставь десятку, пиши в platforms.txt  -std=gnu++1z (заместо -std=gnu++11) и присоединяйся к веселью!

Куды нам, я 80% здесь написанного не понимаю. :( 

Осталось сделать на си динамическое создание веб страниц и все будет в шоколаде.

astwo

http://cppcms.com/wikipp/ru/page/main

Но это не в среде ардуино.

Согласен... был же нормальный язык, 20 операторов, три вида скобочек...

Ой, не прибедняйтесь.

Женя! Тема твоя, но может прогодится?

ОФФТОП

команда для эльфа из /tmp каталога (сборочный каталог) такая:

avr-objdump -S -l -C -h -t -I ./sketch <имя проекта>.elf

показывает на экране. Обычно этого достаточно, но можно украсить жизнь финтифлюшкой.

"Рецепты" из ардуино иде не принимают перенаправление вывода. Поэтому, для полной автоматизации процесса нужно написать скриптик и положить его куда-то. Например туда, где компилятор лежит.

Вот такой скриптик, он для Линукса. У того, кто "дошёл до жизни такой" хватит ума переписать для "винды богомерзкой". ;)))) Путь не нужно повторять в мой домашний каталог! ;)))

#!/bin/sh
#
/home/wlad/ArduinoIDE/hardware/tools/avr/bin/avr-objdump -S -l -C -h -t -I $1 $2 | /usr/bin/tee $3

и вот так его подключить к копированию хекса в папку проекта:

## Save hex
recipe.output.tmp_file={build.project_name}.hex
recipe.output.save_file={build.project_name}.{build.variant}.hex
## добавка для дизассемблера
recipe.hooks.savehex.presavehex.1.pattern="{compiler.path}avr-elf2S.sh" {build.path}/sketch {build.path}/{build.project_name}.elf  {sketch_path}/{build.project_name}.sss

Тогда, при нажатии на "Экспорт бинарного файла", в папку ляжет и дизассемблер.

-----------

сорри, что не написал - это platform.txt ессно! ;))) а то не все продвинуты.

static constexpr uint32_t halfPeriod = 125;

template <uint8_t pin = LED_BUILTIN> class ThePin {
	uint32_t m_old;
	void Set(const bool state) const { digitalWrite(pin, state); }
	bool isLow(void) const { return !(uint8_t)digitalRead(pin); }
public:	
	ThePin(void) { pinMode(pin, OUTPUT); }
	auto operator() (void) {
		 return [=] {  
		 	if (const uint32_t cur = millis(); cur - m_old > halfPeriod) {
		 		m_old = cur; 
		 		Set(isLow()); 
		 	}
		}; 
	}
};

void setup(void) {} 

void loop(void) {
	static ThePin pin;
	pin()();
}

а быстрее можно?

В первой строке задаётся половина периода в миллисекундах.

static constexpr uint32_t halfPeriod = 125;

template <uint8_t pin = LED_BUILTIN> class ThePin {
	uint32_t m_old;
	void Set(const bool state) const { digitalWrite(pin, state); }
	bool isLow(void) const { return !(uint8_t)digitalRead(pin); }
public:	
	ThePin(void) { pinMode(pin, OUTPUT); }
	auto operator() (void) {
		 return [=] {  
		 	if (const uint32_t cur = millis(); cur - m_old > halfPeriod) {
		 		m_old = cur; 
		 		Set(isLow()); 
		 	}
		}; 
	}
};

void setup(void) {} 

void loop(void) {
	static ThePin pin;
	pin()();
}

Можно. Но это уже в Ищю исполнителя. 

а где он лежит platform.txt этот? не сочтите за наглость

<где установлена IDE>\hardware\arduino\avr

Спасибо, Влад.

static constexpr uint32_t halfPeriod = 125;

template <uint8_t pin = LED_BUILTIN> class ThePin {
	uint32_t m_old;
	void Set(const bool state) const { digitalWrite(pin, state); }
	bool isLow(void) const { return !(uint8_t)digitalRead(pin); }
public:	
	ThePin(void) { pinMode(pin, OUTPUT); }
	auto operator() (void) {
		 return [=] {  
		 	if (const uint32_t cur = millis(); cur - m_old > halfPeriod) {
		 		m_old = cur; 
		 		Set(isLow()); 
		 	}
		}; 
	}
};

void setup(void) {} 

void loop(void) {
	static ThePin pin;
	pin()();
}

мне не лениво проверить, теоретически здесь 1 миллисекунда, щас посмотрю )))

А чего там смотреть, меньше миллисекунды быть не может, millis дробных частей не выдаёт.

Поставил .10, поправил platform.txt (только -std=...) ну и сразу начались сложности, пишет 

cc1.exe*: warning: command line option -std=gnu++1z is valid for C++\ObjC++ but not for C

и для классов, которые унаследованы от класса с виртуальным деструктором пишет, например

AnalogSensor.h:64: undefined reference to operator delete(void*, unsigned int) 

в родительском классе деструктор определен так

новый стандарт выявил пахнущий код?))

надо опцию supress warning level 4))

Давай по порядку.

Это ты не в тудой поставил. Ты поставил в строку "compiler.c.flags=...". А надо было в "compiler.cpp.flag"

Ну, про это я забыл сказать :(

Обычно это не вызывает ошибок, только предупреждение, но вот у тебя такие деструкторы используются, потому ошибка.

Там надо просто в файл ...\hardware\arduino\avr\cores\arduino\new.cpp, прямо в евойный хвост, добавить две новые функции

void operator delete(void * ptr, unsigned int) {
  free(ptr);
}

void operator delete[](void * ptr, unsigned int) {
  free(ptr);
}

Сделай, и всё заработает.

спасибо, счас пропробоваем. 

Upd.  Да, всё заработало как встарь.  Благодарю категорически, налью при случае