Arduino.ru

#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
#include <PWM.h>
#define outPWM  9   //пин для генератора сигналов (не менять) - это выход на Мосфет управления форсунками. 

#define buzzer         3    // пин пищалки
#define FUELRelay      4    // пин реле топливного насоса
#define VALVERelay     7    // пин реле клапанов слива

#define pressBut       650  // частота тона нажатия клавиш
#define time_presstone 90   // длительность тона нажатия клавиш

#include <Button.h> // библиотека для создания различных видов нажитий на кнопки плюс защита от дребезга, спасибо КЛАПАУЦИЮ!. 
Button test;    

LiquidCrystal_I2C lcd(0x27, 20, 4); // адрес LCD на шине i2c и  строчность LCD 
         


byte PWM = 128;         //стартовое значение ШИМ (от 0 до 255)

byte frequency = 7; //стартовое значение частоты в Гц
                    //(соответсвует 840 об/мин)

byte Menu=4;    // номера меню, по умолчанию меню "старт теста"

bool last5 = 0;

bool pwm = 1;   // ЗДЕСЬ НУЖНО ВЫБРАТЬ ЛОГИКУ ВЫХОДА ШИМ - ПРЯМАЯ ИЛИ ОБРАТНАЯ,
//В ЗАВИСИМОСТИ ОТ ТОГО, КАКАЯ ЛОГИКА НА ВХОДЕ МОСФЕТА. РУЛИМ ПРИ ЭТОМ "МИНУСОМ" ФОРСУНКИ!!! Т.Е. ОДИН ВЫВОД ФОРСУНКИ +12В, ВТОРОЙ - К ВЫХОДУ МОСФЕТА. 
//  0 - ОБРАТНЫЙ ШИМ,   1 - ПРЯМОЙ ШИМ
// ОБРАТНЫЙ ШИМ - 100% ШИМ СООТВЕТСТВУЕТ ПОЛНОМУ СИГНАЛУ "GND" НА ВЫХОДЕ МОСФЕТА
// ПРЯМОЙ ШИМ -   100% ШИМ СООСТВЕТСВУЕТ ПОЛНОМУ СИГНАЛУ "12В" НА ВЫХОДЕ МОСФЕТА 

float t = 3.00;              // время впрыска, мсек
uint32_t testtime = 30;      // время теста, сек
bool full = 1;               // флаг режима полное открытие форсунок
unsigned long time, timer=0; // для таймера отсчета времени теста
bool timerenabled=false;     // для таймера отсчета времени теста
bool Delay = 0;              // для таймера delay
uint32_t  timerDelay = 0;    // для таймера delay

bool timerenabledOPENvalve = 0; // для таймера отсчета времени на открытие иглы форсунки
uint32_t  timerValve = 0;       // для таймера отсчета времени на открытие иглы форсунки
uint32_t prev = 0;              // для таймера периодического вывода инфы на экран



enum but {LEVO, MENU, PRAVO, FUEL, STOP, VALVE};  // кнопки стенда


bool longpressLEVO = 0;   // флаг длительного удержания кнопки
bool longpressPRAVO = 0;  // флаг длительного удержания кнопки
bool longpressMENU = 0;   // флаг длительного удержания кнопки

bool menu = 0;       // флаг вывелось или нет на экран новое меню 

bool Impedance = 1;  // сопротивление обмотки форсунки true - больше 10 Ом, false - менее 5 Ом

void setup()
{
//ниже настройка пина пищалки
pinMode (buzzer,     OUTPUT); digitalWrite (buzzer,     LOW);
pinMode (FUELRelay,  OUTPUT); digitalWrite (FUELRelay,  LOW);
pinMode (VALVERelay, OUTPUT); digitalWrite (VALVERelay, LOW);  


//ниже настройка библиотеки работы кнопок
test.NO(); // N.O. Normal Open
test.pullUp();
test.duration_bounce       (  50);
unsigned long duration_check = 200;
test.duration_click_Db     (duration_check);
test.duration_inactivity_Up(duration_check);
test.duration_inactivity_Dn(600);
test.duration_press        (500);

//enum but {LEVO, MENU, PRAVO, FUEL, STOP, VALVE};
test.button( 10,   11,    12,    6,    5,    8  ); // соответствующие пины ардуино, к которым подключены кнопки

//ниже настройка LCD
lcd.begin();
lcd.backlight();

//ниже настройка выхода PWM
 InitTimersSafe(); 
 SetPinFrequencySafe(outPWM, frequency); 

if (!pwm){ pwmWrite(outPWM, 255);}
else {pwmWrite(outPWM, 0);}

//ниже мелодия при включении
tone(buzzer,659,150);
delay(150);
tone(buzzer,659,300);
delay(300);
tone(buzzer,659,150);
delay(300);
tone(buzzer,523,150);
delay(150);
tone(buzzer,659,300);
delay(300);
tone(buzzer,784,600);
    }   


void loop() {

test.read();   // обновление состояния кнопок

// ниже опрос длительных нажатий на кнопки
if (test.event_inactivity_Dn(LEVO) ==1)   longpressLEVO = 1;
if (test.event_click_Up (LEVO) == 1)      longpressLEVO = 0;
if (test.event_inactivity_Dn(PRAVO) ==1)  longpressPRAVO =1;
if (test.event_click_Up (PRAVO) == 1)     longpressPRAVO =0;

if (test.event_click_Dn  (FUEL)) {digitalWrite (FUELRelay, !digitalRead(FUELRelay)); tone (buzzer, pressBut, time_presstone);}

if (test.event_click_Dn  (STOP)) {   // при нажатии кнопки "экстренный стоп" всё выключаем
    digitalWrite (FUELRelay, 0);
 if (!pwm){pwmWrite(outPWM, 255);}
      else {pwmWrite(outPWM, 0);}
      timerenabled=false;
      tone (buzzer, 1500, 1500);
                                 }

if (test.event_click_Dn  (VALVE)) {digitalWrite (VALVERelay, 1); tone (buzzer, pressBut, time_presstone);}
if (test.event_click_Up  (VALVE)) {digitalWrite (VALVERelay, 0); }



if (Menu==0){//меню выбора Частоты вращения ДВС
             
             if (!menu){lcd.setCursor(3,3);
             lcd.print("N/min"); 
             lcd.print(" >>         "); menu=1;}
             
             if (test.event_click_Dn  (LEVO) == 1 || (longpressLEVO && !Delay)) {
              
              full=0;
              frequency--;
              if(frequency<1){frequency=1;}
              if (longpressLEVO) {Delay = 1; timerDelay = time;}
              else tone (buzzer, pressBut, time_presstone);
              PWMrefresh();
            }
            if (test.event_click_Dn  (PRAVO) == 1 || (longpressPRAVO && !Delay)) {
           
              full=0;
              frequency++; if (frequency>83) frequency=83;
              if (longpressPRAVO) {Delay = 1; timerDelay = time;}
              else tone (buzzer, pressBut, time_presstone);
              PWMrefresh();
            }  
}
if (Menu==1){//меню выбора длины импульса (времени) впрыска
            
             if (!menu){lcd.setCursor(3,3);
            lcd.print("millisec");
            lcd.print(" >>      "); menu=1;}
          
            if (test.event_click_Dn  (LEVO) == 1 || (longpressLEVO && !Delay)) {
              full=0;
              t-=0.1;
              if (t<1.00) t=1.00;
              if (longpressLEVO) {Delay = 1; timerDelay = time;}
              else tone (buzzer, pressBut, time_presstone);
              PWMrefresh();
                                                                      }
            
            
            if (test.event_click_Dn  (PRAVO) == 1 || (longpressPRAVO && !Delay)) {
              full=0;
              t+=0.1;
              if (t>11.00) t=11.00;
              if (longpressPRAVO) {Delay = 1; timerDelay = time;}   
              else tone (buzzer, pressBut, time_presstone);
              PWMrefresh();     
                                                                        }
            
            }

if (Menu==2) {  // меню выбора/отмены режима постоянного открытия форсунок

if (!menu){lcd.setCursor(3,3);
lcd.print("Full On/Off");
lcd.print(" >>   "); menu=1;}  
  
  if(!timerenabled) if (test.event_click_Dn  (LEVO) == 1 ||  test.event_click_Dn  (PRAVO) == 1) 
  {full=!full; tone (buzzer, pressBut, time_presstone);}
  
             }

            
if (Menu==3) {  // меню выбора времени теста

if (!menu){lcd.setCursor(3,3);
lcd.print("TIME TEST");
lcd.print(" >>   "); menu=1;}

if( !timerenabled){
              if (test.event_click_Dn  (LEVO) == 1 || (longpressLEVO && !Delay)) {
              if (testtime>=5) testtime-=5;
              
              if (longpressLEVO) {Delay = 1; timerDelay = time;}
              else tone (buzzer, pressBut, time_presstone);                                                          }
              
              if (test.event_click_Dn  (PRAVO) == 1 || (longpressPRAVO && !Delay)) {
              testtime+=5;
              if(testtime>600){testtime=600;} 
              if (longpressPRAVO) {Delay = 1; timerDelay = time;}
              else tone (buzzer, pressBut, time_presstone);                                                             }
            
            }          }  

if (Menu==4) { // меню старт

 if (!menu){lcd.setCursor(3,3);
 lcd.print("STOP     START");
 lcd.print(" >>");  menu=1;}

if (!timerenabled && test.event_click_Dn  (PRAVO) == 1){ 
  timer=time; 
  timerenabled=true; 
  tone (buzzer, 1500, 700);   
  PWMrefresh();
  
  }
  
  
            
if (test.event_click_Dn  (LEVO) == 1){
  if (!pwm){pwmWrite(outPWM, 255);}
  else {pwmWrite(outPWM, 0);}
  timerenabled=false;
  tone (buzzer, pressBut, time_presstone);  
  }
  

}

if (Menu==5) {// меню выбора сопротивления обмотки форсунки

if (!menu){lcd.setCursor(3,3);
lcd.print("IMPEDANCE");
lcd.print(" >>     "); menu=1;}

if (!timerenabled) {if (test.event_click_Dn  (LEVO) == 1 ||  test.event_click_Dn  (PRAVO) == 1) 
{Impedance=!Impedance; tone (buzzer, pressBut, time_presstone);  }} 
}



// ниже работа таймера времени теста

time = millis();

if (Delay && time - timerDelay>93 ) Delay = 0;

  if (timerenabled) {
if (timerenabledOPENvalve && time - timerValve > 1000) timerenabledOPENvalve = 0;
  
   if (!timerenabledOPENvalve && full) 
    {
      if (Impedance){
       if (!pwm)pwmWrite(outPWM, 10);
       else     pwmWrite(outPWM, 245);    
                    }
      else {
        if (!pwm)pwmWrite(outPWM, 90);
        else     pwmWrite(outPWM, 165);    
           }
    }

        
    if ((time-timer)>(testtime*1000)) {
      if (!pwm){pwmWrite(outPWM, 255);}
      else {pwmWrite(outPWM, 0);}
      timerenabled=false;
      tone (buzzer, 1500, 1500); 
      
            }
                    }

    
if (test.event_click_Dn (MENU) == 1){ //переключение менюшек
  Menu++; menu = 0; tone (buzzer, pressBut, time_presstone);
  if(Menu>=6){Menu=0;}
} 


// ниже обновление информации на LCD

if (millis () - prev>100){
lcd.setCursor(14,1);
int sec; sec= testtime - ((time - timer)/1000);
    if (timerenabled){  lcd.print(sec);lcd.print("   ");}
  else lcd.print ("00 ");

lcd.setCursor(0,0);
if (!full){
lcd.print("inj=");
lcd.print(t);
lcd.print("msec ");
lcd.setCursor(0,1);
lcd.print("N=");
long frequencyX=frequency*120;
lcd.print(frequencyX); 
if (frequencyX>9999) lcd.print(" RPM  ");
else lcd.print(" RPM   "); 
}
else {lcd.print ("FULL mode    "); lcd.setCursor(0,1); lcd.print ("OPEN         ");
lcd.setCursor(4,2);
lcd.print("Imp: ");
if (Impedance) lcd.print (">10 Ohm ");
else lcd.print ("<5 Ohm  ");

}


lcd.setCursor(14,0);
lcd.print(testtime); lcd.print("sec  ");

  lcd.setCursor(0,3);

   lcd.print("<< ");    
      
      
lcd.display();
prev = millis();
}
}


// ниже фукнция включения выхода PWM

void PWMrefresh(){
  SetPinFrequencySafe(outPWM, frequency);
  if (!full)PWM=frequency*t*0.255;
    else PWM=255; 
    if(PWM<0)PWM=0;
    if(PWM>255)PWM=255;
  if (full) {timerenabledOPENvalve=1; timerValve = time; SetPinFrequencySafe(outPWM, 4000);}
  if (timerenabled){
  if (!pwm){ pwmWrite(outPWM, 255-PWM);}
  else {pwmWrite(outPWM, PWM);}
                   }
  }